Excel CHOOSE ฟังก์ชัน

รายละเอียด

ไวยากรณ์และอาร์กิวเมนต์

การใช้งานและตัวอย่าง

• Ex1 - การใช้งานพื้นฐาน: การใช้ CHOOSE ฟังก์ชั่นเพียงอย่างเดียวเพื่อเลือกค่าจากอาร์กิวเมนต์รายการ
• Ex2 - ส่งคืนผลลัพธ์ที่แตกต่างกันตามเงื่อนไขต่างๆ
• Ex3 - ส่งคืนผลลัพธ์จากการคำนวณที่แตกต่างกันตามเงื่อนไข
• Ex4 - เลือกสุ่มจากรายการ
• Ex5 - รวม CHOOSE และ VLOOKUP ฟังก์ชันในการส่งคืนค่าในคอลัมน์ด้านซ้าย
• Ex6 - ส่งคืนวันธรรมดาหรือเดือนตามวันที่กำหนด
• Ex7 - กลับไปที่วันทำงาน / สุดสัปดาห์ถัดไปตามวันนี้

---

รายละเอียด

พื้นที่ CHOOSE ฟังก์ชันส่งคืนค่าจากรายการอาร์กิวเมนต์ค่าตามหมายเลขดัชนีที่กำหนด ตัวอย่างเช่น, CHOOSE(3,”Apple”,”Peach”,”Orange”) ส่งคืน Orange หมายเลขดัชนีคือ 3 และ Orange เป็นค่าที่สามหลังหมายเลขดัชนีในฟังก์ชัน

ไวยากรณ์และอาร์กิวเมนต์

ไวยากรณ์ของสูตร

CHOOSE(index_num, value1, [value2], …)

ข้อโต้แย้ง

Index_num: จำเป็น ค่าตัวเลขระหว่าง 1-254 ถึงทางอ้อมซึ่งจะเลือกค่าอาร์กิวเมนต์ ถ้า index_num อยู่นอกสเกลระหว่าง 1-254 CHOOSE ส่งคืนไฟล์ #VALUE! ค่าความผิดพลาด ถ้า index_num เป็นค่าทศนิยมค่านั้นจะถูกปัดเศษเป็นจำนวนเต็มก่อนที่จะใช้สูตร Value1: จำเป็น ค่าแรกในสูตรที่สามารถเลือกได้ Value2: ไม่จำเป็น. ค่าที่สองและสูงสุด 254 ที่จะเลือก

Value1, value2…อาจเป็นตัวเลขข้อความสูตรการอ้างอิงเซลล์หรือชื่อที่กำหนด

ราคาย้อนกลับ

พื้นที่ CHOOSE ฟังก์ชันส่งคืนค่าจากรายการตามตำแหน่งที่กำหนด

การใช้งานและตัวอย่าง

ในส่วนนี้ฉันจะแสดงตัวอย่างง่ายๆ แต่เป็นตัวแทนเพื่ออธิบายการใช้งานไฟล์ CHOOSE ฟังก์ชัน

Ex1 - การใช้งานพื้นฐาน: การใช้ CHOOSE ฟังก์ชั่นเพียงอย่างเดียวเพื่อเลือกค่าจากอาร์กิวเมนต์รายการ

สูตร 1:

=CHOOSE(3,"a","b","c","d")

ผลตอบแทน: c ซึ่งเป็นอาร์กิวเมนต์ที่สามหลังจาก index_num ของ 3 ในไฟล์ CHOOSE ฟังก์ชัน

หมายเหตุ: ใช้เครื่องหมายคำพูดคู่รอบค่าถ้าเป็นข้อความ

สูตร 2:

=CHOOSE(2,A1,A2,A3,A4)

ผลตอบแทน: Kate ค่าของ A2 เนื่องจาก index_num คือ 2 และ A2 คือค่าที่สองในไฟล์ CHOOSE ฟังก์ชัน

สูตร 3:

=CHOOSE(4,8,9,7,6)

Return: 6 อาร์กิวเมนต์รายการที่ 4 ในฟังก์ชัน

---

Ex2 - ส่งคืนผลลัพธ์ที่แตกต่างกันตามเงื่อนไขต่างๆ

สมมติว่าคุณมีรายการเบี่ยงเบนสำหรับผลิตภัณฑ์แต่ละรายการซึ่งจำเป็นต้องติดป้ายกำกับตามเงื่อนไขดังภาพด้านล่างที่แสดง

โดยปกติคุณสามารถใช้ฟังก์ชัน IF เพื่อจัดการได้ แต่ที่นี่ฉันจะแนะนำวิธีใช้ไฟล์ CHOOSE เพื่อแก้ปัญหานี้ได้อย่างง่ายดาย

สูตร:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

อธิบาย:

(B7>0)+(B7>1)+(B7>5): index_num, B7 คือ 2 ซึ่งใหญ่กว่า 0 และ 1 แต่น้อยกว่า 5 ดังนั้นเราจึงได้ผลลัพธ์ระดับกลาง:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

ดังที่เราทราบ True = 1, False = 0 ดังนั้นจึงสามารถดูสูตรได้ดังนี้:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

แล้วก็

=CHOOSE(2,"Top","Middle","Bottom")

ผลลัพธ์: กลาง

---

Ex3 - ส่งคืนผลลัพธ์จากการคำนวณที่แตกต่างกันตามเงื่อนไข

สมมติว่าคุณต้องคำนวณส่วนลดสำหรับแต่ละผลิตภัณฑ์ตามจำนวนและราคาตามภาพด้านล่างที่แสดง:

สูตร:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

อธิบาย:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 คือ 102 ซึ่งมากกว่า 100 แต่น้อยกว่า 201 ดังนั้นในส่วนนี้จะส่งกลับผลลัพธ์ที่แสดงเป็น:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

แล้วก็

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: ค่าที่จะเลือกคืนเท่ากับราคา * จำนวน * เปอร์เซ็นต์เงินคืนเนื่องจากที่นี่ index_num คือ 2 จึงเลือก B8 * C8 * 0.2

ผลตอบแทน: 102 * 2 * 0.2 = 40.8

---

Ex4 - เลือกสุ่มจากรายการ

ใน Excel บางครั้งคุณอาจต้องสุ่มเลือกค่าจากรายการที่กำหนดซึ่งก็คือ CHOOSE ฟังก์ชั่นสามารถแก้งานนี้ได้

สุ่มเลือกหนึ่งค่าจากรายการ:

สูตร:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

อธิบาย:

RANDBETWEEN(1,5): index_num สุ่มรับหมายเลขระหว่าง 1 ถึง 5

$D$2,$D$3,$D$4,$D$5,$D$6: รายการค่าที่จะเลือก

---

Ex5 - รวม CHOOSE และ VLOOKUP ฟังก์ชันในการส่งคืนค่าในคอลัมน์ด้านซ้าย

โดยทั่วไปเราใช้ฟังก์ชัน VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) เพื่อส่งคืนค่าตามค่าที่กำหนดจากช่วงตาราง แต่ด้วยความที่ VLOOKUP ฟังก์ชันจะส่งคืนค่าความผิดพลาดในขณะที่คอลัมน์ส่งคืนอยู่ทางด้านซ้ายของคอลัมน์การค้นหาดังภาพด้านล่างที่แสดง:

ในกรณีนี้คุณสามารถรวมไฟล์ CHOOSE ด้วยฟังก์ชัน VLOOKUP เพื่อแก้ปัญหา

สูตร:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

อธิบาย:

CHOOSE({1,2},B1:B7,A1:A7): เป็นอาร์กิวเมนต์ table_range ในฟังก์ชัน VLOOKUP {1,2} หมายถึงการแสดง 1 หรือ 2 เป็นอาร์กิวเมนต์ index_num ตามอาร์กิวเมนต์ col_num ในฟังก์ชัน VLOOKUP ที่นี่ col_num ในฟังก์ชัน VLOOKUP คือ 2 ดังนั้นไฟล์ CHOOSE ฟังก์ชันแสดงเป็น CHOOSE(2, B1:B7,A1:A7)หมายถึงการเลือกค่าจาก A1: A7

---

Ex6 - ส่งคืนวันธรรมดาหรือเดือนตามวันที่กำหนด

กับ CHOOSE คุณยังสามารถส่งคืนวันธรรมดาและเดือนที่สัมพันธ์กันตามวันที่ที่กำหนด

สูตร 1: กลับวันธรรมดาตามวันที่

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

อธิบาย:

WEEKDAY(): อาร์กิวเมนต์ index_num เพื่อรับหมายเลขวันธรรมดาของวันที่ที่กำหนดตัวอย่างเช่น WEEKDAY (A5) ส่งกลับ 6 จากนั้นอาร์กิวเมนต์ index_num คือ 6

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": อาร์กิวเมนต์รายการค่าเริ่มต้นด้วย "วันอาทิตย์" เนื่องจากหมายเลขวันธรรมดา "1" หมายถึง "วันอาทิตย์"

สูตร 2: คืนเดือนตามวันที่

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

อธิบาย:

MONTH(): อาร์กิวเมนต์ index_num ซึ่งรับหมายเลขเดือนจากวันที่ที่กำหนดตัวอย่างเช่น MONTH (A5) ส่งกลับ 3

---

Ex7 - กลับไปที่วันทำงาน / สุดสัปดาห์ถัดไปตามวันนี้

ในการทำงานประจำวันคุณอาจต้องการคำนวณวันทำงานถัดไปหรือวันหยุดสุดสัปดาห์ตามวันนี้ ที่นี่ CHOOSE ฟังก์ชั่นยังสามารถช่วยคุณได้

ตัวอย่างเช่นวันนี้คือ 12/20/2018 วันพฤหัสบดีตอนนี้คุณต้องได้รับวันทำงานและวันหยุดถัดไป

สูตร 1: รับวันที่ของวันนี้

=TODAY()

ผลลัพธ์: 12/20/2018

สูตร 2: รับหมายเลขวันทำงานของวันนี้

=WEEKDAY(TODAY())

ผลลัพธ์: 5 (วันนี้คือ 12/20/2018)

รายการหมายเลขวันธรรมดาตามภาพด้านล่างนี้:

สูตร 3: รับวันทำงานถัดไป

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

อธิบาย:

Today(): คืนวันที่ปัจจุบัน

WEEKDAY(TODAY()): index_num อาร์กิวเมนต์ใน CHOOSE ฟังก์ชันรับหมายเลขวันทำงานของวันนี้เช่นวันอาทิตย์ 1 วันจันทร์คือ 2 ...

1,1,1,1,1,3,2: อาร์กิวเมนต์รายการค่าใน CHOOSE ฟังก์ชัน ตัวอย่างเช่นถ้าวันธรรมดา (วันนี้ ()) ส่งกลับ 1 (วันอาทิตย์) ก็จะเลือก 1 ในรายการค่าจากนั้นสูตรทั้งหมดจะเปลี่ยนเป็น = วันนี้ () + 1 ซึ่งหมายถึงการเพิ่ม 1 วันเพื่อกลับมาในวันจันทร์หน้า ถ้าวันธรรมดา (วันนี้ ()) ส่งกลับ 6 (วันศุกร์) ระบบจะเลือก 3 จากรายการค่าเพราะวันศุกร์อยู่ห่างจากวันจันทร์หน้าไป 3 วัน

ผลลัพธ์ (ในขณะที่วันนี้คือ 12/20/2018):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12/20/2018 + 1

= 12/21/2018

สูตร 4: รับวันหยุดสุดสัปดาห์ถัดไป

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

อธิบาย:

6,5,4,3,2,1,1: อาร์กิวเมนต์รายการค่าใน CHOOSE ฟังก์ชัน ตัวอย่างเช่นหากวันธรรมดา (วันนี้ ()) ส่งกลับ 1 (วันอาทิตย์) ก็จะเลือก 6 จากรายการค่าจากนั้นสูตรทั้งหมดจะเปลี่ยนเป็น = วันนี้ () + 6 ซึ่งหมายถึงการเพิ่ม 6 วันและกลับมาในวันเสาร์ถัดไป

ผลลัพธ์:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12/20/2018 + 2

= 12/22/2018

---

ไฟล์ตัวอย่าง