ลบรหัสประเทศจากหมายเลขโทรศัพท์ของผู้ติดต่อ

ลบรหัสประเทศจากหมายเลขโทรศัพท์ของผู้ติดต่อด้วย VBA

หากคุณต้องการเพียงแค่ลบรหัสประเทศออกจากหมายเลขโทรศัพท์ของผู้ติดต่อหนึ่งหมายเลขคุณสามารถลบด้วยตนเองได้ดังนี้:

1 ใน คน (หรือ ติดต่อ) ดูคลิก รายละเอียด > เปลี่ยนมุมมอง > เบอร์โทรศัพท์. ดูภาพหน้าจอ:

2. ดับเบิลคลิกเพื่อเปิดผู้ติดต่อที่มีหมายเลขโทรศัพท์ที่คุณจะลบหมายเลขประเทศออก

3. ในหน้าต่างผู้ติดต่อที่เปิดอยู่ให้ลบเครื่องหมายบวกและรหัสประเทศออกจากโทรศัพท์ที่ระบุในไฟล์ เบอร์โทรศัพท์ แล้วคลิก ติดต่อ > บันทึกและปิด.

จนถึงขณะนี้รหัสประเทศถูกลบออกจากหมายเลขโทรศัพท์ที่ระบุตามภาพด้านล่างที่แสดง:

หากคุณต้องการลบรหัสประเทศออกจากหมายเลขโทรศัพท์ทั้งหมดของผู้ติดต่อทั้งหมดใน Outlook ขอแนะนำให้ใช้ VBA เพื่อจัดการกับมันอย่างง่ายดาย

1 ใน คน (หรือ ติดต่อ) ดูเปิดโฟลเดอร์ผู้ติดต่อที่คุณจะลบรหัสประเทศออกจากผู้ติดต่อทั้งหมด

2 กด อื่น ๆ + F11 คีย์พร้อมกันเพื่อเปิดหน้าต่าง Microsoft Visual Basic for Applications

3 คลิก สิ่งที่ใส่เข้าไป > โมดูลจากนั้นวางโค้ด VBA ด้านล่างลงในสคริปต์โมดูลการเปิดใหม่

VBA: ลบรหัสประเทศจากหมายเลขโทรศัพท์ทั้งหมดของผู้ติดต่อทั้งหมด

Sub FixPhoneFormat()

 Dim oFolder As MAPIFolder
Set oFolder = Application.ActiveExplorer.CurrentFolder

 If Left(UCase(oFolder.DefaultMessageClass), 11) <> "IPM.CONTACT" Then
MsgBox "You need to select a Contacts folder", vbExclamation
Exit Sub
End If

Dim nCounter As Integer
nCounter = 0

Dim oItem
For Each oItem In oFolder.Items
Dim oContact As ContactItem

          If TypeName(oItem) <> "DistListItem" Then
Set oContact = oItem
With oContact
.AssistantTelephoneNumber = FixFormatUSPhone(.AssistantTelephoneNumber)
.Business2TelephoneNumber = FixFormatUSPhone(.Business2TelephoneNumber)
.BusinessFaxNumber = FixFormatUSPhone(.BusinessFaxNumber)
.BusinessTelephoneNumber = FixFormatUSPhone(.BusinessTelephoneNumber)
.CallbackTelephoneNumber = FixFormatUSPhone(.CallbackTelephoneNumber)
.CarTelephoneNumber = FixFormatUSPhone(.CarTelephoneNumber)
.CompanyMainTelephoneNumber = FixFormatUSPhone(.CompanyMainTelephoneNumber)
.Home2TelephoneNumber = FixFormatUSPhone(.Home2TelephoneNumber)
.HomeFaxNumber = FixFormatUSPhone(.HomeFaxNumber)
.HomeTelephoneNumber = FixFormatUSPhone(.HomeTelephoneNumber)
.ISDNNumber = FixFormatUSPhone(.ISDNNumber)
.MobileTelephoneNumber = FixFormatUSPhone(.MobileTelephoneNumber)
.OtherFaxNumber = FixFormatUSPhone(.OtherFaxNumber)
.OtherTelephoneNumber = FixFormatUSPhone(.OtherTelephoneNumber)
.PagerNumber = FixFormatUSPhone(.PagerNumber)
.PrimaryTelephoneNumber = FixFormatUSPhone(.PrimaryTelephoneNumber)
.RadioTelephoneNumber = FixFormatUSPhone(.RadioTelephoneNumber)
.TelexNumber = FixFormatUSPhone(.TelexNumber)
.TTYTDDTelephoneNumber = FixFormatUSPhone(.TTYTDDTelephoneNumber)

.Save

nCounter = nCounter + 1
End With
End If
Next

MsgBox nCounter & " contacts processed.", vbInformation

End Sub

Private Function FixFormatUSPhone(Phone As String) As String

Phone = Trim(Phone)
FixFormatUSPhone = Phone
If Phone = "" Then Exit Function
Dim prefix As String
prefix = Left(Phone, 1)

' Configured for US
' Enter the correct prefix here
Do While (prefix = "+" Or prefix = "1")

' if the prefix is 2 digits, change to 4;
' if 3 digits, change to 5
Phone = Mid(Phone, 3)
prefix = Left(Phone, 1)
Loop

' After we clean up the country code, we remove non-numeric characters
' Can be tweaked to change formatting, ie: change 202.555.1212 to 202-555-1212

 Phone = Replace(Phone, "(", "")
Phone = Replace(Phone, ")", "")
Phone = Replace(Phone, ".", "")
Phone = Replace(Phone, " ", "")
Phone = Replace(Phone, "-", "")

 FixFormatUSPhone = Phone

End Function

4 กด F5 หรือคลิกปุ่ม Ruปุ่ม n เพื่อเรียกใช้ VBA นี้

5. จากนั้นกล่องโต้ตอบจะปรากฏขึ้นและแสดงจำนวนผู้ติดต่อที่ได้รับการประมวลผลโปรดคลิกที่ OK เพื่อปิด

ตอนนี้คุณจะเห็นรหัสประเทศถูกลบออกจากหมายเลขโทรศัพท์ทุกประเภทจากผู้ติดต่อทั้งหมด ดูภาพหน้าจอ:

ติดตามการโทรด้วยวารสารใน Outlook

ค้นหาผู้ติดต่อตามหมายเลขโทรศัพท์ใน Outlook