วิธีบันทึกข้อความอีเมลเป็นรูปแบบรูปภาพ (jpg / tiff) ใน Outlook?

คุณเคยพยายามบันทึกข้อความอีเมลเป็นรูปภาพเช่น jpg หรือ tiff picture ใน Outlook หรือไม่? บทความนี้จะแสดงวิธีการแก้ปัญหานี้

บันทึกข้อความอีเมลเป็นรูปแบบรูปภาพด้วยรหัส VBA

บันทึกข้อความอีเมลเป็นรูปแบบรูปภาพด้วยรหัส VBA

โปรดทำดังนี้เพื่อบันทึกข้อความอีเมลเป็นรูปแบบรูปภาพใน Outlook

1. เลือกอีเมลที่คุณจะบันทึกเป็นรูปภาพจากนั้นกดปุ่ม อื่น ๆ + F11 พร้อมกันเพื่อเปิดไฟล์ Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2 ใน Microsoft Visual Basic สำหรับแอปพลิเคชัน โปรดคลิก สิ่งที่ใส่เข้าไป > แบบฟอร์มผู้ใช้. ดูภาพหน้าจอ:

3 สร้าง a แบบฟอร์มผู้ใช้ ดังภาพด้านล่างที่แสดง

4 เลือก ตัวเลือก jpg และเปลี่ยนชื่อเป็น opbJPG ทางด้านซ้าย อสังหาริมทรัพย์ บานหน้าต่าง

5. ทำซ้ำขั้นตอนที่ 4 ด้านบนเพื่อเปลี่ยนชื่อปุ่มตัวเลือกอื่นเป็น opbTIFF. และเปลี่ยนชื่อ OK ปุ่มคำสั่งและ ยกเลิก ปุ่มคำสั่งเป็น cdbตกลง และ cdbยกเลิก แยกต่างหาก

หมายเหตุ: ถ้า อสังหาริมทรัพย์ บานหน้าต่างไม่แสดงในไฟล์ Microsoft Visual Basic สำหรับแอปพลิเคชัน โปรดคลิกที่ F4 กุญแจสำคัญในการเปิดบานหน้าต่าง

6. ดับเบิลคลิกที่พื้นที่ว่างบนฟอร์มผู้ใช้เพื่อเปิดไฟล์ รหัส หน้าต่าง. แทนที่โค้ดทั้งหมดด้วยสคริปต์ VBA ต่อไปนี้ จากนั้นปิดหน้าต่างรหัส

รหัส VBA 1: บันทึกข้อความอีเมลเป็นรูปภาพ

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7 เลือก แบบฟอร์มผู้ใช้1 และเปลี่ยนชื่อเป็น FrmPicType ใน อสังหาริมทรัพย์ บานหน้าต่างดังภาพหน้าจอด้านล่างที่แสดง

8 คลิก สิ่งที่ใส่เข้าไป > โมดูลจากนั้นคัดลอกโค้ด VBA ด้านล่างลงในหน้าต่างโมดูล

รหัส VBA 2: บันทึกข้อความอีเมลเป็นรูปภาพ

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9 คลิก เครื่องมือ > อ้างอิงตรวจสอบไฟล์ ไลบรารีวัตถุ Microsoft PowerPoint แลวคลิกปุ the ม OK ปุ่ม. ดูภาพหน้าจอ: