วิธีย้ายรายการที่ถูกลบประเภทต่าง ๆ ไปยังโฟลเดอร์ต่าง ๆ โดยอัตโนมัติใน Outlook?

ใน Outlook รายการที่ถูกลบทุกประเภท (เมล งาน ผู้ติดต่อ ฯลฯ) จะถูกย้ายไปยังโฟลเดอร์รายการที่ถูกลบ หากคุณต้องการย้ายรายการไปยังโฟลเดอร์ต่างๆ ตามประเภทรายการภายใต้โฟลเดอร์รายการที่ถูกลบดังที่แสดงภาพหน้าจอด้านล่าง คุณจะสร้างใน Outlook ได้อย่างไร

ย้ายรายการประเภทต่าง ๆ ที่ถูกลบไปยังโฟลเดอร์ต่าง ๆ โดยอัตโนมัติด้วยรหัส VBA

รหัส VBA ด้านล่างสามารถช่วยคุณย้ายรายการที่ถูกลบไปยังโฟลเดอร์ต่างๆ โดยอัตโนมัติ โปรดดำเนินการดังนี้:

1. เปิด Outlook จากนั้นกด . ค้างไว้ ALT + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2. จากนั้นดับเบิลคลิก นี้OutlookSession จาก โครงการ - โครงการ 1 บานหน้าต่าง จากนั้น คัดลอกและวางโค้ดด้านล่างลงในหน้าต่างโค้ดเปล่า:

รหัส VBA: ย้ายรายการประเภทต่างๆ ที่ถูกลบไปไว้ในโฟลเดอร์ต่างๆ โดยอัตโนมัติ

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub