Outlook: วิธีส่งอีเมลอีกครั้งโดยอัตโนมัติหากไม่มีการตอบกลับ

ผู้เขียน: ซัน แก้ไขล่าสุด: 2024-09-03

เมื่อคุณส่งอีเมลถึงเพื่อนร่วมงานหรือหุ้นส่วนสหกรณ์หรือใครบางคนและต้องการคำตอบอย่างเร่งด่วน คุณสามารถตั้งค่าการตั้งค่าการส่งอีเมลใหม่อัตโนมัติได้ หากการตอบกลับยังไม่มาถึงก่อนเวลาที่กำหนด

ใช้ Reminder และ VBA เพื่อตั้งค่าส่งใหม่อัตโนมัติหากไม่มีการตอบสนอง

ใช้ Reminder และ VBA เพื่อตั้งค่าส่งใหม่อัตโนมัติหากไม่มีการตอบสนอง

ส่วนที่ 1: ตั้งเตือนให้เตือนในเวลาที่กำหนด

1. คลิกขวาที่อีเมล (จากโฟลเดอร์รายการที่ส่ง) ที่คุณต้องการส่งใหม่หากไม่มีการตอบกลับ ในเมนูบริบทที่ปรากฏขึ้น ให้คลิก ติดตาม > เพิ่มคำเตือน.

2. ใน popping ประเพณี กล่องโต้ตอบเก็บไฟล์ เตือน เลือกช่องทำเครื่องหมาย จากนั้นในกล่องดรอปดาวน์ด้านล่าง ให้เลือกวันที่และเวลาที่คุณต้องการให้การตอบกลับมาก่อน นอกจากนี้ คุณยังสามารถพิมพ์วันที่และเวลาลงในช่องได้โดยตรง คลิก OK.

ส่วนที่ 2: แทรก VBA เพื่อส่งอีเมลอีกครั้งหากไม่มีการตอบสนองในเวลาที่กำหนด

3 กด อื่น ๆ + F11 คีย์เพื่อเปิดใช้งานไฟล์ Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

4 ดับเบิลคลิก นี้OutlookSession ใน โครงการ – โครงการ1 เพื่อสร้างสคริปต์เปล่า และคัดลอกและวางโค้ด VBA ด้านล่างลงในสคริปต์เปล่า

VBA: ส่งอีเมลอีกครั้งหากไม่มีการตอบกลับ

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. บันทึกรหัส จากนั้นกลับไปที่อินเทอร์เฟซหลัก คลิก เนื้อไม่มีมัน > Options และใน the ตัวเลือก Outlook หน้าต่างคลิก ศูนย์ความเชื่อถือ ในบานหน้าต่างด้านซ้ายและคลิก การตั้งค่าศูนย์ความเชื่อถือ เพื่อเปิดใช้งาน ศูนย์ความเชื่อถือ หน้าต่าง. คลิก การตั้งค่ามาโคร และตรวจสอบให้แน่ใจว่า เปิดใช้งานมาโครทั้งหมด (ไม่แนะนำให้ใช้รหัสที่เป็นอันตรายซึ่งอาจทำงานได้) ตัวเลือกถูกเลือกไว้ในส่วนด้านขวา คลิก OK > OK.

6. ตอนนี้หากอีเมลที่ส่งซึ่งได้รับการตั้งค่าด้วยการเตือนไม่ได้รับการตอบกลับเมื่อถึงเวลาที่กำหนด กล่องโต้ตอบ popping จะปรากฏขึ้นเพื่อเตือนคุณว่าจะส่งอีเมลอีกครั้งเพื่อแจ้งเตือนหรือไม่