จะตอบกลับตามปกติในโฟลเดอร์รายการที่ส่งจาก Outlook ได้อย่างไร 

โดยปกติเมื่อคุณคลิกคุณสมบัติตอบกลับในโฟลเดอร์รายการที่ส่งเพื่อส่งข้อความเพิ่มเติมอื่นสำหรับบุคคลที่คุณส่งที่อยู่อีเมลของคุณเองจะแสดงที่ฟิลด์ถึงตามภาพหน้าจอต่อไปนี้ อาจเป็นเรื่องที่น่ารำคาญสำหรับคุณในการเปลี่ยนที่อยู่ในแต่ละครั้ง จะทำให้ Outlook ใช้ที่อยู่ผู้รับเดิมไม่ใช่ของคุณได้อย่างไร

ตอบกลับตามปกติในโฟลเดอร์รายการที่ถูกส่งจาก Outlook พร้อมคุณสมบัติตอบกลับทั้งหมด

ตอบกลับตามปกติในโฟลเดอร์รายการที่ถูกส่งจาก Outlook ด้วยรหัส VBA

---

ตอบกลับตามปกติในโฟลเดอร์รายการที่ถูกส่งจาก Outlook พร้อมคุณสมบัติตอบกลับทั้งหมด

ใน Outlook ไฟล์ ตอบทั้งหมด คุณสมบัติสามารถช่วยคุณแก้ปัญหานี้ได้โปรดทำตามนี้:

เมื่อคุณต้องการตอบกลับอีเมลที่ส่งเพื่อส่งอีกครั้งเพื่อรักษาที่อยู่ของผู้รับเดิมโปรดคลิก ตอบทั้งหมด และที่อยู่ของผู้รับเดิมจะอยู่ที่ ไปยัง ฟิลด์ดังภาพหน้าจอต่อไปนี้ที่แสดง:

---

ตอบกลับตามปกติในโฟลเดอร์รายการที่ถูกส่งจาก Outlook ด้วยรหัส VBA

บางครั้งคุณอาจลืมไฟล์ ตอบทั้งหมด เมื่อตอบกลับข้อความที่ส่งดังนั้นโค้ด VBA ด้านล่างนี้สามารถช่วยให้คุณตอบกลับได้ตามปกติในโฟลเดอร์รายการที่ถูกส่งโดยใช้คุณสมบัติตอบกลับ ทำตามขั้นตอนต่อไปนี้:

1. กด ALT + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2. ใน Microsoft Visual Basic สำหรับแอปพลิเคชัน ดับเบิลคลิก นี้OutlookSession จาก โครงการ 1 (VbaProject.O ™) บานหน้าต่างเพื่อเปิดโหมดจากนั้นคัดลอกและวางรหัสต่อไปนี้ลงในโมดูลเปล่า

รหัส VBA: ตอบกลับตามปกติในโฟลเดอร์รายการที่ส่งจาก Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. จากนั้นบันทึกรหัสและรีสตาร์ท Outlook เพื่อใช้เอฟเฟกต์โค้ดตอนนี้เมื่อคลิก ตอบ เพื่อส่งอีเมลอีกครั้งใน รายการที่ถูกส่ง ที่อยู่ของผู้รับเดิมจะแสดงที่ช่องถึงตามที่คุณต้องการ