วิธีพิมพ์งานตามหมวดหมู่ใน Outlook

สมมติว่ามีประเภทสีต่างๆในงาน Outlook ของคุณและตอนนี้คุณต้องการพิมพ์รายการงานตามประเภทในหน้าต่างๆ คุณจะแก้งานนี้ใน Outlook ได้อย่างไร

พิมพ์งานตามหมวดหมู่ในหน้าต่างๆด้วยตนเองทีละหน้า

พิมพ์งานตามหมวดหมู่ในหน้าต่างๆด้วยรหัส VBA

พิมพ์งานตามหมวดหมู่ในหน้าต่างๆด้วยตนเองทีละหน้า

ใน Outlook คุณสามารถพิมพ์งานด้วยตนเองตามหมวดหมู่ต่างๆในหน้าต่างๆทีละหน้าได้โปรดดำเนินการดังนี้:

1. เปิด Outlook และไปที่บานหน้าต่างงานแล้วเลือกโฟลเดอร์งานที่คุณต้องการพิมพ์จากนั้นกด Ctrl + E เพื่อเปิดใช้งานไฟล์ ค้นหา จากนั้นภายใต้ ค้นหา คลิกแท็บ หมวดหมู่ ไอคอนและเลือกหมวดหมู่สีที่คุณต้องการพิมพ์ดูภาพหน้าจอ:

งานพิมพ์เอกสารตามประเภท 1

2. จากนั้นงานทั้งหมดที่มีประเภทสีเฉพาะจะแสดงรายการพร้อมกันดูภาพหน้าจอ:

งานพิมพ์เอกสารตามประเภท 2

3. จากนั้นไปที่คลิก เนื้อไม่มีมัน > พิมพ์ เพื่อพิมพ์รายการงานนี้ตามภาพหน้าจอต่อไปนี้:

งานพิมพ์เอกสารตามประเภท 3

4. ทำซ้ำขั้นตอนข้างต้นเพื่อพิมพ์รายการงานด้วยหมวดหมู่สีอื่น ๆ ด้วยตนเอง

พิมพ์งานตามหมวดหมู่ในหน้าต่างๆด้วยรหัส VBA

นี่คือรหัส VBA ที่สามารถช่วยคุณพิมพ์งานตามหมวดหมู่ในหน้าต่างๆพร้อมกันได้โปรดทำตามขั้นตอนต่อไปนี้:

1. ไปที่ งาน บานหน้าต่างและเลือกโฟลเดอร์งานที่คุณต้องการพิมพ์

2. จากนั้นกดไฟล์ ALT + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

3. จากนั้นคลิก สิ่งที่ใส่เข้าไป > โมดูลคัดลอกและวางโค้ดด้านล่างลงในโมดูลเปล่าที่เปิดอยู่:

รหัส VBA: พิมพ์งานตามหมวดหมู่ในหน้าต่างๆ:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. จากนั้นคลิก เครื่องมือ > อ้างอิง ใน Microsoft Visual Basic สำหรับแอปพลิเคชัน ในหน้าต่างที่โผล่ออกมา เอกสารอ้างอิง - โครงการ 1 กล่องโต้ตอบตรวจสอบ ไลบรารีวัตถุ Microsoft Excel และ รันไทม์การเขียนสคริปต์ของ Microsoft ตัวเลือกจากไฟล์ อ้างอิงที่มีอยู่ กล่องรายการดูภาพหน้าจอ:

งานพิมพ์เอกสารตามประเภท 4