จะตั้งค่าสถานะอีเมลโดยอัตโนมัติตามไฟล์แนบเฉพาะใน Outlook ได้อย่างไร

เมื่อได้รับอีเมลบางฉบับที่มีไฟล์แนบที่สำคัญบางฉบับคุณอาจต้องแจ้งว่าไม่เหมาะสมเพื่อที่คุณจะสามารถค้นหาได้อย่างรวดเร็วและง่ายดายสำหรับการส่งต่อ บทความนี้ฉันจะพูดถึงวิธีง่ายๆในการตั้งค่าสถานะอีเมลโดยอัตโนมัติว่าไฟล์แนบใดมีชื่อเฉพาะ

ตั้งค่าสถานะอีเมลโดยอัตโนมัติตามไฟล์แนบที่ระบุด้วยรหัส VBA

ตั้งค่าสถานะอีเมลโดยอัตโนมัติตามไฟล์แนบที่ระบุด้วยรหัส VBA

หากต้องการตั้งค่าสถานะอีเมลที่มีไฟล์แนบเฉพาะโดยอัตโนมัติโปรดใช้รหัส VBA ต่อไปนี้:

1. เปิด Outlook จากนั้นกดไฟล์ ALT + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2. ใน Microsoft Visual Basic สำหรับแอปพลิเคชัน ดับเบิลคลิก นี้OutlookSession จาก โครงการ 1 (VbaProject.O ™) บานหน้าต่างเพื่อเปิดโหมดใหม่จากนั้นคัดลอกและวางรหัสต่อไปนี้ลงในโมดูลเปล่า

รหัส VBA: ตั้งค่าสถานะอีเมลโดยอัตโนมัติตามไฟล์แนบเฉพาะ:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

หมายเหตุ: ในโค้ดด้านบนคุณสามารถเปลี่ยนนามสกุลไฟล์และชื่อไฟล์แนบได้ตามต้องการ

3. จากนั้นบันทึกรหัสและรีสตาร์ท Outlook เพื่อให้รหัสมีผลตอนนี้เมื่อได้รับอีเมลที่ชื่อไฟล์แนบมีข้อความที่ระบุ Outlook จะตั้งค่าสถานะอีเมลนี้โดยอัตโนมัติเพื่อติดตามผลดูภาพหน้าจอ: