วิธีเปลี่ยนลายเซ็นโดยอัตโนมัติตามผู้รับใน Outlook?

ผู้เขียน : ซิลูเวีย แก้ไขล่าสุด: 2024-09-13

ตามค่าเริ่มต้น Outlook มีฟังก์ชันในตัวสำหรับผู้ใช้ในการเปลี่ยนลายเซ็นโดยอัตโนมัติในขณะที่ส่งอีเมลผ่านบัญชีอีเมลอื่น แต่นอกเหนือจากนั้นที่นี่ฉันจะแสดงวิธีการเปลี่ยนลายเซ็นโดยอัตโนมัติตามผู้รับที่แตกต่างกันในฟิลด์ถึงใน Outlook

เปลี่ยนลายเซ็นตามผู้รับโดยอัตโนมัติด้วยรหัส VBA

เปลี่ยนลายเซ็นตามผู้รับโดยอัตโนมัติด้วยรหัส VBA

โปรดทำตามขั้นตอนด้านล่างเพื่อใช้ลายเซ็นที่แตกต่างกันกับผู้รับที่เกี่ยวข้องขณะส่งอีเมลใน Outlook

1. ประการแรกคุณต้องปิดใช้งานคุณลักษณะลายเซ็นที่แนบอัตโนมัติใน Outlook กรุณาคลิก เนื้อไม่มีมัน > Options เพื่อเปิด ตัวเลือกของ outlook หน้าต่าง

2 ใน ตัวเลือกของ outlook เลือก จดหมาย ในบานหน้าต่างด้านซ้ายจากนั้นคลิกไฟล์ ลายเซ็น ปุ่มใน เขียนข้อความ มาตรา. ดูภาพหน้าจอ:

การใช้ VBA เพื่อเปลี่ยนลายเซ็นตามผู้รับโดยอัตโนมัติด้วยโค้ด

3 ใน ลายเซ็นและเครื่องเขียน ให้ไปที่ไฟล์ เลือกลายเซ็นเริ่มต้น ภายใต้ ลายเซ็นอีเมล เลือกบัญชีอีเมลใน บัญชีอีเมล์ รายการแบบหล่นลงจากนั้นเลือก (ไม่มี) จาก ข้อความใหม่ และ ตอบกลับ / ส่งต่อ รายการแบบเลื่อนลง ทำซ้ำขั้นตอนเหล่านี้จนกว่าบัญชีอีเมลทั้งหมดจะถูกตั้งค่าเป็น (ไม่มี). จากนั้นคลิกปุ่ม OK ปุ่ม

การใช้ VBA เพื่อเปลี่ยนลายเซ็นตามผู้รับโดยอัตโนมัติด้วยโค้ด VBA

หมายเหตุ: คุณยังสามารถสร้างลายเซ็นที่คุณต้องการได้ในสิ่งนี้ ลายเซ็นและเครื่องเขียน กล่องโต้ตอบ

4 คลิกที่ OK ปุ่มเมื่อส่งกลับไฟล์ ตัวเลือกของ outlook หน้าต่าง

5 กด อื่น ๆ + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

6 ใน Microsoft Visual Basic สำหรับแอปพลิเคชัน ดับเบิลคลิก นี้OutlookSession ในบานหน้าต่างด้านซ้ายเพื่อเปิดหน้าต่างรหัสและคัดลอกโค้ด VBA ด้านล่างลงในหน้าต่าง ดูภาพหน้าจอ:

รหัส VBA: เปลี่ยนลายเซ็นโดยอัตโนมัติตามผู้รับใน Outlook

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by ExtendOffice 2022/08/01
Dim xMailItem As MailItem
Dim xRecipients As Recipients
Dim xRecipient As Recipient
Dim xRcpAddress As String
Dim xSignatureFile, xSignaturePath As String
Dim xFSO As Scripting.FileSystemObject
Dim xDoc As Document
Dim xFindStr As String
On Error Resume Next
Set xFSO = New Scripting.FileSystemObject
If Item.Class <> olMail Then Exit Sub
Set xMailItem = Item
Set xRecipients = xMailItem.Recipients
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
For Each xRecipient In xRecipients
    If xRecipient.AddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Then
        xRcpAddress = xRecipient.AddressEntry.GetExchangeUser.PrimarySmtpAddress
    Else
        xRcpAddress = xRecipient.AddressEntry.Address
    End If
    Select Case xRcpAddress
        Case "Email Address 1"
            xSignatureFile = xSignaturePath & "aaa.htm"
            Exit For
        Case "Email Address 2", "Email Address 3"
            xSignatureFile = xSignaturePath & "bbb.htm"
            Exit For
        Case "Email Address 4"
            xSignatureFile = xSignaturePath & "ccc.htm"
            Exit For
    End Select
Next
VBA.DoEvents
Set xDoc = xMailItem.GetInspector.WordEditor
xFindStr = "From: " & xMailItem.Recipients.Item(1).Name & " <" & xRcpAddress & ">"
If VBA.InStr(1, xMailItem.Body, xFindStr) <> 0 Then
    xDoc.Application.Selection.HomeKey Unit:=wdStory, Extend:=wdMove
    With xDoc.Application.Selection.Find
        .ClearFormatting
        .Text = xFindStr
        .Execute Forward:=True
    End With
    With xDoc.Application.Selection
        .MoveLeft wdCharacter, 2
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
Else
    With xDoc.Application.Selection
        .EndKey Unit:=wdStory, Extend:=wdMove
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
End If
xDoc.Application.Selection.InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
End Sub

หมายเหตุ : :

1). ในโค้ด VBA โปรดแทนที่ "ที่อยู่อีเมล 1/2/3/4" พร้อมที่อยู่อีเมลของผู้รับโดยเฉพาะ
2). "aaa.htm""bbb.htm"และ"ccc.htm" เป็นลายเซ็นเฉพาะที่คุณจะส่งไปยังผู้รับที่เกี่ยวข้อง
3). ในกรณีนี้ให้ลงนาม "AAA" จะถูกส่งไปที่ "ที่อยู่อีเมล 1", ลายเซ็น "BBB" จะถูกส่งไปที่ "ที่อยู่อีเมล 2"และ"ที่อยู่อีเมล 3"และ "ที่อยู่อีเมล 4" จะได้รับอีเมล์พร้อมลายเซ็น "CCC" กรุณาเปลี่ยนแปลงตามความต้องการของคุณ
4). หากอีเมลมีผู้รับหลายคน รหัสจะพิจารณาเฉพาะผู้รับคนแรกเท่านั้น ในกรณีนี้ ผู้รับรายอื่นจะได้รับอีเมลที่มีลายเซ็นเดียวกันกับผู้รับรายแรก

7 จากนั้นคลิก เครื่องมือ > อ้างอิง ไป เอกสารอ้างอิง - โครงการ กล่องโต้ตอบ ในกล่องโต้ตอบโปรดตรวจสอบทั้ง ไลบรารีวัตถุ Microsoft Word และ รันไทม์การเขียนสคริปต์ของ Microsoft จากนั้นคลิก OK ปุ่มดูภาพหน้าจอ:

8 กด อื่น ๆ + Q ปุ่มเพื่อปิดไฟล์ Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

จากนี้ไปหลังจากเขียนอีเมลและกดปุ่มส่งลายเซ็นที่เกี่ยวข้องจะถูกแทรกโดยอัตโนมัติที่ส่วนท้ายของเนื้อหาอีเมลตามที่อยู่อีเมลของผู้รับในช่องถึง

หากคุณต้องการแทรกการประทับเวลาเป็นลายเซ็นลงในเนื้อหาอีเมลในขณะที่สร้าง / ตอบกลับ / ส่งต่ออีเมลใหม่ใน Outlook ของคุณคุณสามารถเปิดใช้งาน เพิ่มลายเซ็นวันที่เมื่อสร้างใหม่ตอบกลับและส่งต่ออีเมล ตัวเลือกของ Kutools สำหรับ Outlook เพื่อบรรลุมัน ดูภาพหน้าจอ:
ดาวน์โหลดและทดลองใช้ทันที (เส้นทางฟรี 30 วัน)

การใช้ VBA เพื่อเปลี่ยนลายเซ็นตามผู้รับโดยอัตโนมัติด้วยโค้ด VBA