วิธีซ่อนหมายเลขแฟกซ์ใน Select Names List ใน Outlook

ผู้เขียน: ซัน แก้ไขล่าสุด: 2024-08-30

ใน Outlook คุณอาจพบว่าในรายการ“ เลือกชื่อ” หรือสมุดที่อยู่คอลัมน์ที่อยู่อีเมลไม่เพียง แต่ประกอบด้วยที่อยู่อีเมลเท่านั้น แต่ยังรวมถึงรายการแฟกซ์ที่อาจรบกวนคุณ ในบทความนี้จะแนะนำวิธีการซ่อนหมายเลขแฟกซ์ให้กับคุณ
doc ซ่อนหมายเลขแฟกซ์ 1

ซ่อนหมายเลขแฟกซ์ในรายการเลือกชื่อด้วย VBA

ซ่อนหมายเลขแฟกซ์ในรายการเลือกชื่อด้วย VBA

หากคุณต้องการซ่อนหมายเลขแฟกซ์ที่มีอยู่ในรายการเลือกชื่อโปรดดำเนินการดังนี้:

1 กด Alt + F11 คีย์เพื่อเปิดใช้งาน Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2 คลิก สิ่งที่ใส่เข้าไป > โมดูล หากต้องการแทรกโมดูลเปล่าใหม่ให้คัดลอกและวางโค้ดด้านล่างลงในสคริปต์

VBA: ซ่อนหมายเลขแฟกซ์ที่มีอยู่ในเลือกชื่อ

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3 กด F5 เพื่อเรียกใช้รหัสตอนนี้หมายเลขแฟกซ์ถูกซ่อนแล้ว
doc ซ่อนหมายเลขแฟกซ์ 2

หากคุณต้องการซ่อนหมายเลขแฟกซ์ในรายชื่อใหม่ให้ดำเนินการดังนี้:

1 กด Alt + F11 คีย์เพื่อเปิดใช้งาน Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2 ดับเบิลคลิก นี้OutlookSession เริ่มต้น โครงการ 1 บานหน้าต่างจากนั้นคัดลอกและวางโค้ดด้านล่างลงในสคริปต์

VBA: ซ่อนหมายเลขแฟกซ์ในรายชื่อใหม่ที่เพิ่มเข้ามา

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub

3. บันทึกรหัสและรีสตาร์ท Outlook เพื่อให้รหัสมีผล

จากนี้ไปหมายเลขแฟกซ์ทั้งหมดของผู้ติดต่อที่สร้างขึ้นใหม่จะซ่อนอยู่ในหน้าต่างเลือกชื่อ: ผู้ติดต่อ

AI Mail Assistant ใน Outlook: การตอบกลับที่ชาญฉลาดยิ่งขึ้น การสื่อสารที่ชัดเจนยิ่งขึ้น (เวทย์มนตร์เพียงคลิกเดียว!) ฟรี

ปรับปรุงงาน Outlook ประจำวันของคุณด้วย AI Mail Assistant จาก Kutools for Outlook เครื่องมืออันทรงพลังนี้เรียนรู้จากอีเมลที่ผ่านมาของคุณเพื่อให้การตอบกลับที่ชาญฉลาดและแม่นยำ เพิ่มประสิทธิภาพเนื้อหาอีเมลของคุณ และช่วยให้คุณร่างและปรับแต่งข้อความได้อย่างง่ายดาย

คุณสมบัตินี้รองรับ:

การตอบกลับอัจฉริยะ: รับการตอบกลับที่สร้างขึ้นจากการสนทนาที่ผ่านมาของคุณ ปรับแต่ง แม่นยำ และพร้อมใช้งาน
เนื้อหาที่ได้รับการปรับปรุง: ปรับแต่งข้อความอีเมลของคุณโดยอัตโนมัติเพื่อความชัดเจนและผลกระทบ
องค์ประกอบที่ง่ายดาย: เพียงระบุคำหลัก แล้วปล่อยให้ AI จัดการที่เหลือด้วยสไตล์การเขียนที่หลากหลาย
ส่วนขยายอัจฉริยะ: ขยายความคิดของคุณด้วยคำแนะนำที่คำนึงถึงบริบท
สรุป: รับภาพรวมโดยย่อของอีเมลขนาดยาวทันที
การเข้าถึงทั่วโลก: แปลอีเมลของคุณเป็นภาษาต่างๆ ได้อย่างง่ายดาย

คุณสมบัตินี้รองรับ: