วิธีลบไฟล์แนบบางประเภทออกจากอีเมลใน Outlook

คุณเคยพยายามลบไฟล์แนบในอีเมลที่เลือกหลายฉบับตามประเภทไฟล์ใน Outlook หรือไม่? เช่นการลบไฟล์แนบ docx หรือ png ทั้งหมดออกจากอีเมลที่เลือก คุณจะแก้งานนี้ใน Outlook ได้อย่างไร

ลบไฟล์แนบบางประเภทออกจากอีเมลด้วยรหัส VBA

ลบไฟล์แนบบางประเภทออกจากอีเมลด้วยรหัส VBA

หากต้องการลบไฟล์แนบบางประเภทออกจากอีเมลที่เลือกรหัส VBA ต่อไปนี้สามารถช่วยคุณได้โปรดทำตามนี้:

1. เลือกอีเมลที่คุณต้องการลบไฟล์แนบประเภทที่ระบุในรายชื่ออีเมล

2. กด ALT + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

3. จากนั้นคลิก สิ่งที่ใส่เข้าไป > โมดูลคัดลอกและวางโค้ดด้านล่างลงในโมดูลว่างที่เปิดดูภาพหน้าจอ:

รหัส VBA: ลบไฟล์แนบบางประเภทออกจากอีเมล:

Sub DeleteSpecificTypeOfAttachments()
Dim xSelection As Outlook.Selection
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xAttachment As Outlook.Attachment
Dim xFileType As String
Dim xType As String
Dim xFSO As Scripting.FileSystemObject
Dim I As Integer
On Error Resume Next
Set xSelection = Outlook.Application.ActiveExplorer.Selection
Set xFSO = New Scripting.FileSystemObject
xType = ""
xType = InputBox("Attachment Type:", "Kutools for Outlook", xType, 8)
If Len(Trim(xType)) = 0 Then Exit Sub
For Each xItem In xSelection
    If xItem.Class = olMail Then
        Set xMailItem = xItem
       If xMailItem.Attachments.Count > 0 Then
            For I = xMailItem.Attachments.Count To 1 Step -1
                Set xAttachment = xMailItem.Attachments.Item(I)
                xFileType = xFSO.GetExtensionName(xAttachment.FileName)
                If InStr(xFileType, Trim(xType)) > 0 Then
                    xAttachment.Delete
                End If
            Next I
            xMailItem.Save
        End If
    End If
Next
Set xMailItem = Nothing
Set xFSO = Nothing
End Sub

4. แล้วก็ยังอยู่ใน Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่างคลิก เครื่องมือ > อ้างอิง ไป เอกสารอ้างอิง - โครงการ 1 กล่องโต้ตอบและตรวจสอบ รันไทม์การเขียนสคริปต์ของ Microsoft ตัวเลือกจาก อ้างอิงที่มีอยู่ กล่องรายการดูภาพหน้าจอ:

doc ลบไฟล์แนบตามประเภท 1