ในการลบโฟลเดอร์ย่อยว่างทั้งหมดของโฟลเดอร์ Outlook บางโฟลเดอร์โปรดทำดังนี้:

1. กด อื่น ๆ + F11 ปุ่มเพื่อเปิดหน้าต่าง Microsoft Visual Basic for Applications

2. คลิก สิ่งที่ใส่เข้าไป > โมดูลและวางโค้ด VBA ด้านล่างลงในหน้าต่างโมดูลใหม่

VBA: ลบโฟลเดอร์ย่อยที่ว่างทั้งหมดของโฟลเดอร์ Outlook บางโฟลเดอร์จำนวนมาก

Public Sub DeletindEmtpyFolder()
Dim xFolders As Folders
Dim xCount As Long
Dim xFlag As Boolean
Set xFolders = Application.GetNamespace("MAPI").PickFolder.Folders
Do
FolderPurge xFolders, xFlag, xCount
Loop Until (Not xFlag)
If xCount > 0 Then
MsgBox "Deleted " & xCount & "(s) empty folders", vbExclamation + vbOKOnly, "Kutools for Outlook"
Else
MsgBox "No empty folders found", vbExclamation + vbOKOnly, "Kutools for Outlook"
End If
End Sub

Public Sub FolderPurge(xFolders, xFlag, xCount)
Dim I As Long
Dim xFldr As Folder 'Declare sub folder objects
xFlag = False
If xFolders.Count > 0 Then
For I = xFolders.Count To 1 Step -1
Set xFldr = xFolders.Item(I)
If xFldr.Items.Count < 1 Then 'If the folder is empty check for subfolders
If xFldr.Folders.Count < 1 Then 'If the folder contains not sub folders confirm deletion
xFldr.Delete 'Delete the folder
xFlag = True
xCount = xCount + 1
Else 'Folder contains sub folders so confirm deletion
FolderPurge xFldr.Folders, xFlag, xCount
End If
Else 'Folder contains items or (subfolders that may be empty).
FolderPurge xFldr.Folders, xFlag, xCount
End If
Next
End If
End Sub

3. กด F5 คีย์หรือ วิ่ง เพื่อเรียกใช้รหัส VBA นี้

4. ในกล่องโต้ตอบเลือกโฟลเดอร์ที่เปิดขึ้นมาโปรดเลือกโฟลเดอร์เฉพาะที่มีโฟลเดอร์ย่อยว่างที่คุณจะลบจำนวนมากแล้วคลิก OK ปุ่ม. ดูภาพหน้าจอ:

5. ตอนนี้กล่องโต้ตอบ Kutools for Outlook จะปรากฏขึ้นและแสดงให้คุณเห็นว่ามีการลบโฟลเดอร์ย่อยว่างจำนวนเท่าใด คลิก OK เพื่อปิด

จนถึงขณะนี้โฟลเดอร์ย่อยทั้งหมดของโฟลเดอร์ Outlook ที่ระบุได้ถูกลบไปแล้วจำนวนมาก