จะรับที่อยู่อีเมลของผู้ส่งจากอีเมลหนึ่งฉบับขึ้นไปใน Outlook ได้อย่างไร

คุณเคยพยายามแยกที่อยู่อีเมลออกจากช่อง "จาก" ของอีเมลที่ได้รับตั้งแต่หนึ่งฉบับขึ้นไปใน Outlook หรือไม่? บทความนี้มีโค้ด VBA เพื่อช่วยคุณจัดการงานนี้

รับที่อยู่อีเมลของผู้ส่งจากอีเมลหนึ่งฉบับขึ้นไปใน Outlook

โปรดเรียกใช้รหัส VBA ต่อไปนี้เพื่อแยกที่อยู่อีเมลจากช่อง "จาก" ของอีเมลที่ได้รับอย่างน้อยหนึ่งฉบับใน Outlook

1. เปิดโฟลเดอร์อีเมล เลือกข้อความอีเมลที่คุณต้องการรับที่อยู่อีเมลของผู้ส่ง กด อื่น ๆ + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

เคล็ดลับ: หากต้องการเลือกหลายอีเมล โปรดกด . ค้างไว้ Ctrl คีย์แล้วเลือกอีเมลทีละรายการ

2 ใน Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่างคลิก สิ่งที่ใส่เข้าไป > โมดูลจากนั้นคัดลอกโค้ด VBA ต่อไปนี้ไปยังหน้าต่างโมดูล (โค้ด)

รหัส VBA: แยกที่อยู่อีเมลของผู้ส่งออกจากอีเมลอย่างน้อยหนึ่งรายการใน Outlook

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3 คลิก เครื่องมือ > อ้างอิงจากนั้นตรวจสอบ รันไทม์การเขียนสคริปต์ของ Microsoft กล่องใน ข้อมูลอ้างอิง – Project1 กล่องโต้ตอบ

4 กด F5 กุญแจสำคัญในการเรียกใช้รหัส จากนั้นก Kutools สำหรับ Outlook กล่องโต้ตอบปรากฏขึ้น โดยแสดงรายการที่อยู่อีเมลของผู้ส่งทั้งหมดของอีเมลที่เลือก

เคล็ดลับ:

หากคุณต้องการส่งออกรายการที่อยู่ไปยังไฟล์ txt ให้คลิกที่ ใช่ ปุ่ม

หรือคลิก ไม่ ปุ่มเพื่อสิ้นสุดกระบวนการ