ไปยังเนื้อหาหลัก

วิธีค้นหาข้อความที่ใช้เกณฑ์บ่อยที่สุดใน Excel

บทความนี้จะพูดถึงวิธีการค้นหาข้อความที่เกิดขึ้นบ่อยที่สุดโดยอิงตามเกณฑ์เฉพาะจากช่วงของเซลล์ใน Excel ในเวลาเดียวกันฉันจะแนะนำสูตรสำหรับการแยกข้อความที่เกิดบ่อยที่สุดในคอลัมน์

ค้นหาข้อความที่พบบ่อยที่สุด ค้นหาข้อความที่ใช้บ่อยที่สุดตามเกณฑ์

ค้นหาข้อความที่เกิดขึ้นบ่อยที่สุดในคอลัมน์ด้วยสูตรอาร์เรย์

หากคุณต้องการค้นหาและแยกข้อความที่เกิดขึ้นบ่อยที่สุดจากรายการเซลล์โปรดใช้สูตรด้านล่าง:

ไวยากรณ์ของสูตรทั่วไปคือ:

=INDEX(range, MODE(MATCH(range, range, 0 )))
  • range: is the list of cells that you want to find the most frequent occurring text.

1. ป้อนหรือคัดลอกสูตรนี้ลงในเซลล์ว่างที่คุณต้องการส่งออกผลลัพธ์:

=INDEX(A2:A15,MODE(MATCH(A2:A15,A2:A15,0)))
  • เคล็ดลับ: ในสูตรนี้:
  • A2: A15: คือรายการข้อมูลที่คุณต้องการค้นหาจำนวนครั้งที่ข้อความเกิดขึ้นมากที่สุด

2. จากนั้นกด Ctrl + Shift + Enter คีย์พร้อมกันและคุณจะได้ผลลัพธ์ที่ถูกต้องตามภาพด้านล่างที่แสดง:

ค้นหาข้อความที่เกิดบ่อยที่สุดตามเกณฑ์ด้วยสูตรอาร์เรย์

บางครั้งคุณอาจต้องหาข้อความที่เกิดขึ้นบ่อยที่สุดตามเงื่อนไขเฉพาะเช่นคุณต้องการค้นหาชื่อที่เกิดขึ้นบ่อยที่สุดซึ่ง Project คือ Project A ดังภาพด้านล่างที่แสดง:

ไวยากรณ์ของสูตรทั่วไปคือ:

=INDEX(range1,MODE(IF(range2=criteria, MATCH(rang1,range1,0))))
  • range1: is the range of cells that you want to find the most frequent occurring text.
  • range2=criteria: is the range of cells contain the specific criteria that you want to find name based on.

1. โปรดป้อนหรือคัดลอกสูตรด้านล่างลงในเซลล์ว่าง:

=INDEX($B$2:$B$15,MODE(IF($A$2:$A$15=D2,MATCH($B$2:$B$15,$B$2:$B$15,0))))
  • เคล็ดลับ: ในสูตรนี้:
  • B2: B15: คือรายการข้อมูลที่คุณต้องการค้นหาจำนวนครั้งที่มีชื่อเกิดขึ้นมากที่สุด
  • A2: A15 = D2: คือช่วงของเซลล์ที่มีเกณฑ์เฉพาะที่คุณต้องการค้นหาข้อความตาม

2. จากนั้นกด Ctrl + Shift + Enter คีย์พร้อมกันชื่อที่เกิดขึ้นบ่อยที่สุดของโครงการ A ถูกแยกออกแล้วดูภาพหน้าจอ:

ค้นหาข้อความที่เกิดขึ้นบ่อยที่สุดระหว่างสองวันที่กำหนดด้วยสูตรอาร์เรย์

ส่วนนี้จะพูดถึงวิธีค้นหาข้อความที่พบบ่อยที่สุดซึ่งอยู่ระหว่างวันที่สองวันที่กำหนด ตัวอย่างเช่นหากต้องการค้นหาชื่อที่ใช้บ่อยที่สุดตามวันที่ซึ่งอยู่ระหว่าง 6/28/2019 ถึง 7/5/2019 สูตรอาร์เรย์ต่อไปนี้อาจช่วยคุณได้:

1. โปรดใช้สูตรด้านล่างในเซลล์ว่าง:

=INDEX($B$2:$B$15, MATCH(MODE.SNGL(IF(($A$2:$A$15<=$E$2)*($A$2:$A$15>=$D$2), COUNTIF($B$2:$B$15, "<"&$B$2:$B$15), "")), COUNTIF($B$2:$B$15, "<"&$B$2:$B$15),0))
  • เคล็ดลับ: ในสูตรนี้:
  • B2: B15: คือรายการข้อมูลที่คุณต้องการค้นหาจำนวนครั้งที่มีชื่อเกิดขึ้นมากที่สุด
  • A2: A15 <= E2: คือช่วงของวันที่ที่น้อยกว่าหรือเท่ากับวันที่เฉพาะเจาะจงที่คุณต้องการค้นหาชื่อตาม
  • A2: A15> = D2: คือช่วงของวันที่ที่มากกว่าหรือเท่ากับวันที่เฉพาะเจาะจงที่คุณต้องการค้นหาชื่อตาม

2. จากนั้นกด Ctrl + Shift + Enter คีย์เข้าด้วยกันชื่อที่เกิดขึ้นบ่อยที่สุดระหว่างวันที่สองวันที่ระบุถูกดึงออกมาดูภาพหน้าจอ:

บทความข้อความที่เกี่ยวข้องบ่อยที่สุด:

  • ค้นหาตัวเลขหรือข้อความที่พบบ่อยที่สุดเป็นอันดับสองใน Excel
  • เราสามารถใช้ฟังก์ชัน MODE เพื่อค้นหาตัวเลขที่พบบ่อยที่สุดจากช่วงที่สะดวกใน Excel อย่างไรก็ตามวิธีการค้นหาหมายเลขที่พบบ่อยที่สุดอันดับสองจากคอลัมน์ แล้วถ้าหาค่าข้อความที่พบบ่อยอันดับสองจากคอลัมน์ล่ะ? ที่นี่เรามีวิธีแก้ปัญหาสำหรับคุณ
  • ค้นหาค่าที่พบบ่อยที่สุด (ตัวเลขหรือสตริงข้อความ) จากรายการใน Excel
  • สมมติว่าคุณมีรายชื่อที่มีรายการที่ซ้ำกันและตอนนี้คุณต้องการแยกค่าที่ปรากฏบ่อยที่สุด วิธีโดยตรงคือการนับข้อมูลทีละรายการเพื่อให้ได้ผลลัพธ์ แต่ถ้ามีหลายพันชื่อในคอลัมน์วิธีนี้จะยุ่งยากและใช้เวลานาน บทช่วยสอนต่อไปนี้จะแนะนำเคล็ดลับในการแก้ปัญหานี้อย่างรวดเร็วและสะดวกสบาย
  • จัดเรียงข้อมูลตามค่าที่พบบ่อยที่สุดใน Excel
  • สมมติว่าคุณมีรายการข้อมูลจำนวนมากในแผ่นงานของคุณและตอนนี้คุณต้องการจัดเรียงรายการนี้ตามความถี่ที่แต่ละคำเกิดขึ้น กล่าวคือค่าที่พบบ่อยที่สุด (เช่นเกิดขึ้นสี่ครั้งในคอลัมน์) จะแสดงรายการก่อนจากนั้นตามด้วยคำที่เกิดขึ้นสามครั้งสองครั้งและหนึ่งครั้งตามภาพหน้าจอที่แสดง คุณจะแก้ปัญหานี้ใน Excel ได้อย่างไร

เครื่องมือเพิ่มประสิทธิภาพการทำงานในสำนักงานที่ดีที่สุด

Kutools สำหรับ Excel แก้ปัญหาส่วนใหญ่ของคุณและเพิ่มผลผลิตของคุณได้ถึง 80%

  • ซุปเปอร์ฟอร์มูล่าบาร์ (แก้ไขข้อความและสูตรหลายบรรทัดได้อย่างง่ายดาย); การอ่านเค้าโครง (อ่านและแก้ไขเซลล์จำนวนมากได้อย่างง่ายดาย); วางลงในช่วงที่กรองแล้ว...
  • ผสานเซลล์ / แถว / คอลัมน์ และการเก็บรักษาข้อมูล แยกเนื้อหาของเซลล์ รวมแถวที่ซ้ำกันและผลรวม / ค่าเฉลี่ย... ป้องกันเซลล์ซ้ำ; เปรียบเทียบช่วง...
  • เลือกซ้ำหรือไม่ซ้ำ แถว; เลือกแถวว่าง (เซลล์ทั้งหมดว่างเปล่า); Super Find และ Fuzzy Find ในสมุดงานจำนวนมาก สุ่มเลือก ...
  • สำเนาถูกต้อง หลายเซลล์โดยไม่เปลี่ยนการอ้างอิงสูตร สร้างการอ้างอิงอัตโนมัติ ถึงหลายแผ่น ใส่สัญลักษณ์แสดงหัวข้อย่อย, กล่องกาเครื่องหมายและอื่น ๆ ...
  • แทรกสูตรที่ชื่นชอบและรวดเร็ว, ช่วงแผนภูมิและรูปภาพ; เข้ารหัสเซลล์ ด้วยรหัสผ่าน; สร้างรายชื่อผู้รับจดหมาย และส่งอีเมล ...
  • แยกข้อความ, เพิ่มข้อความ, ลบตามตำแหน่ง, ลบ Space; สร้างและพิมพ์ผลรวมย่อยของเพจ แปลงระหว่างเนื้อหาของเซลล์และความคิดเห็น...
  • ซุปเปอร์ฟิลเตอร์ (บันทึกและใช้โครงร่างตัวกรองกับแผ่นงานอื่น ๆ ); การเรียงลำดับขั้นสูง ตามเดือน / สัปดาห์ / วันความถี่และอื่น ๆ ตัวกรองพิเศษ โดยตัวหนาตัวเอียง ...
  • รวมสมุดงานและแผ่นงาน; ผสานตารางตามคอลัมน์สำคัญ แยกข้อมูลออกเป็นหลายแผ่น; Batch แปลง xls, xlsx และ PDF...
  • การจัดกลุ่มตาราง Pivot ตาม จำนวนสัปดาห์วันในสัปดาห์และอื่น ๆ ... แสดงปลดล็อกเซลล์ที่ถูกล็อก ด้วยสีที่ต่างกัน เน้นเซลล์ที่มีสูตร / ชื่อ...
kte แท็บ 201905
  • เปิดใช้งานการแก้ไขและอ่านแบบแท็บใน Word, Excel, PowerPoint, ผู้จัดพิมพ์, Access, Visio และโครงการ
  • เปิดและสร้างเอกสารหลายรายการในแท็บใหม่ของหน้าต่างเดียวกันแทนที่จะเป็นในหน้าต่างใหม่
  • เพิ่มประสิทธิภาพการทำงานของคุณ 50% และลดการคลิกเมาส์หลายร้อยครั้งให้คุณทุกวัน!
ด้านล่าง officetab
Comments (17)
No ratings yet. Be the first to rate!
Ian
Ian
This comment was minimized by the moderator on the site
Hello, thank you for your help.
I've used the "Find the most frequent occurring text based on criteria with array formulas" which works well for the 14 rows of data in your example however, when I increase the rows (and the formula values to match with CTRL+SHIFT+ENTER) it is still only searching the first 14 rows and returning "N/A" searching for anything past row 14.

I appreciate your help
Thank you
Reply
0
0
Peter
Peter
This comment was minimized by the moderator on the site
Hallo, eine wunderbare Lösung, funktioniert auch super - nur in meinem speziellen Fall noch nicht ganz: wenn im Suchbereich auch Leerzellen sind, also z.B. hier bei "Name" im Bereich "Finden Sie den am häufigsten vorkommenden Text anhand von Kriterien mit Array-Formeln", da sind bei mir auch leere Zellen dabei. Schon kommt überall nur noch "#NV". Gibt es da eine Lösung, um trotzdem noch den häufigsten (Text)-Inhalt zu finden? Vielen Dank!
Reply
0
0
Peter
Peter     Peter
This comment was minimized by the moderator on the site
...bzw. mit der Formel aus #41657 kommt kein #NV mehr, dafür aber auch nur manchmal ein Ergebnis, was nicht Null ist. Manchmal kommt der richtige Wert, häufig halt nur "0". ..:Danke :-)
Reply
0
0
Ryuzaki
Ryuzaki
This comment was minimized by the moderator on the site
Bagaimana jika range yang kita cari terdapat kolom kosongnya? misal kita buat rumus paten raport, kita ingin mencari akhlak umumnya siswa, kita ambil jangkauan terjauh, misal dalam 1 kelas, jumlah maksimal anak 60. pada suatu kelas lain jumlah siswa cuma 50, sehingga kolom 51 sd 60 kosong. apakah rumus demikian masih valid? saya coba kok #N/A atau mohon pencerahannya!
Reply
0
0
Yeslam Bazi
Yeslam Bazi
This comment was minimized by the moderator on the site
Hi, This is great, what I found is that when there is tie or only one record the formula results in N/A. How do I get it to show the single result? this is when I want to find the most common value based on criteria.
Reply
0
0
skyyang
skyyang     Yeslam Bazi
This comment was minimized by the moderator on the site
Hello, Yeslam,
To solve your problem, please apply the follwoing formula:

=IFERROR(INDEX($B$2:$B$15,MODE(IF($A$2:$A$15=D2,MATCH($B$2:$B$15,$B$2:$B$15,0)))),INDEX(B2:B15,MATCH(D2,A2:A15,0)))

Please have a try, hope it can help you!
Reply
Report
0
0
Genna
Genna
This comment was minimized by the moderator on the site
HEY! This is really helpful. I'm wondering if you could help me, with, if there is a tie, to pick one of the top values/strings. thanks!
Reply
0
0
darkhangelsk
darkhangelsk
This comment was minimized by the moderator on the site
This is really helpful. I'm just thinking how to do this with a third criteria for "Find the most frequent text based on criteria"? let say Inventory, Project, Name then get the most occured name.

Thank you so much!
Reply
0
0
skyyang
skyyang     darkhangelsk
This comment was minimized by the moderator on the site
Hello,
To apply the fromula for three criteria, please apply the below formula:
=INDEX($A$2:$A$12,MODE(IF($A$2:$B$12=F2,IF($C$2:$C$12=G2,IF($D$2:$D$12=H2,MATCH($A$2:$A$12,$A$2:$A$12,0))))))


Tips：If you have more criteria, you just need to add the IF criteria as below:
=INDEX(range,MODE(IF(range1=criteria1,IF(range2=criteria2,IF(range3=criteria3,... MATCH(rang,range,0))))))


Please have a try, hope it can help you!
Reply
Report
0
0
Dodik
Dodik
This comment was minimized by the moderator on the site
Halo gan,
bagaimana cara menemukan teks yang paling sering keluar KEDUA, KETIGA dan seterusnya?
Terima kasih :)
Reply
0
0
skyyang
skyyang     Dodik
This comment was minimized by the moderator on the site
Hello, Dodik,
To solve your problem, please use the following formulas: (Please remember to press Ctrl + Shift + Enter keys together to get the result)

Find the second most common value: 
=INDEX(A1:A20,MODE(IF((A1:A20<>"")*(A1:A20<>INDEX(A1:A20,MODE(IF(A1:A20<>"",MATCH(A1:A20,A1:A20,0))))),MATCH(A1:A20,A1:A20,0))))

Find the third most common value: 
=INDEX(A1:A20,MODE(IF(((A1:A20<>"")*(A1:A20<>INDEX(A1:A20,MODE(IF(A1:A20<>"",MATCH(A1:A20,A1:A20,0)))))*(A1:A20<>INDEX(A1:A20,MODE(IF((A1:A20<>"")*(A1:A20<>INDEX(A1:A20,MODE(IF(A1:A20<>"",MATCH(A1:A20,A1:A20,0))))),MATCH(A1:A20,A1:A20,0)))))),MATCH(A1:A20,A1:A20,0))))
Reply
Report
0
0
Lauren
Lauren
This comment was minimized by the moderator on the site
Thank you for this information, but what happens if there is a tie? For the generic example, =INDEX(A2:A15,MODE(MATCH(A2:A15,A2:A15,0))), how would the formula be modified to output text indicating that a majority could not be determined?
Reply
0
0
skyyang
skyyang     Lauren
This comment was minimized by the moderator on the site
Hello, Lauren

If there are more than one result, you can use the below formulas:
First, you can use this array formula: (Note: after inserting the formula, please press Ctrl + Shift + Enter keys together to get the first result.)
=INDEX($A$2:$A$10,MATCH(MIN(MODE(IF(NOT(COUNTIF(C$1:C1,$A$2:$A$10)),(COUNTIF($A$2:$A$10,"<"& $A$2:$A$10)+1)*{1,1}))),COUNTIF($A$2:$A$10,"<"& $A$2:$A$10)+{1},0))

With this formula, you can extract all data from the most occurred value to least common value.
And then, you should use the below formula to count the number of the occurred text:
=COUNTIF($A$2:$A$10, C2)


https://www.extendoffice.com/images/stories/comments/comment-skyyang/doc-most-common-value.png


Please try, hope it can help you!
View Attachments (1 / 5)
Reply
Report
0
0
lecifa6459
lecifa6459
This comment was minimized by the moderator on the site
Very helpful advice in this particular post! It’s the little changes that make the largest changes. Thanks for sharing!  
Reply
Report
0
0
jefferson118
jefferson118
This comment was minimized by the moderator on the site
Thank you for your post, I look for such article along time, today i find it finally. this post give me lots of advise it is very useful for me. website
Reply
0
0
There are no comments posted here yet
Load More
Please leave your comments in English
Guest
Posting as Guest
×
Rate this post:
Reset
0   Characters
Suggested Locations