วิธีบันทึกแผ่นงานเป็นไฟล์ PDF และส่งอีเมลเป็นไฟล์แนบผ่าน Outlook?

ในบางกรณีคุณอาจต้องส่งแผ่นงานเป็นไฟล์ PDF ผ่าน Outlook โดยปกติคุณจะต้องบันทึกแผ่นงานเป็นไฟล์ PDF ด้วยตนเองจากนั้นสร้างอีเมลใหม่โดยใช้ไฟล์ PDF นี้เป็นไฟล์แนบใน Outlook ของคุณและส่งไปในที่สุด การทำทีละขั้นตอนด้วยตนเองใช้เวลานาน ในบทความนี้เราจะแสดงวิธีบันทึกแผ่นงานเป็นไฟล์ PDF อย่างรวดเร็วและส่งเป็นไฟล์แนบโดยอัตโนมัติผ่าน Outlook ใน Excel

บันทึกแผ่นงานเป็นไฟล์ PDF และส่งเป็นไฟล์แนบพร้อมรหัส VBA

บันทึกแผ่นงานเป็นไฟล์ PDF และส่งเป็นไฟล์แนบพร้อมรหัส VBA

คุณสามารถเรียกใช้รหัส VBA ด้านล่างเพื่อบันทึกแผ่นงานที่ใช้งานอยู่เป็นไฟล์ PDF โดยอัตโนมัติจากนั้นส่งเป็นไฟล์แนบทาง Outlook กรุณาดำเนินการดังนี้

1. เปิดแผ่นงานที่คุณจะบันทึกเป็น PDF แล้วส่งจากนั้นกดปุ่ม อื่น ๆ + F11 พร้อมกันเพื่อเปิดไฟล์ Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2 ใน Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่างคลิก สิ่งที่ใส่เข้าไป > โมดูล. จากนั้นคัดลอกและวางโค้ด VBA ด้านล่างลงในไฟล์ รหัส หน้าต่าง. ดูภาพหน้าจอ:

รหัส VBA: บันทึกแผ่นงานเป็นไฟล์ PDF และส่งเป็นไฟล์แนบทางอีเมล

Sub Saveaspdfandsend()
Dim xSht As Worksheet
Dim xFileDlg As FileDialog
Dim xFolder As String
Dim xYesorNo As Integer
Dim xOutlookObj As Object
Dim xEmailObj As Object
Dim xUsedRng As Range

Set xSht = ActiveSheet
Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)

If xFileDlg.Show = True Then
   xFolder = xFileDlg.SelectedItems(1)
Else
   MsgBox "You must specify a folder to save the PDF into." & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Must Specify Destination Folder"
   Exit Sub
End If
xFolder = xFolder + "\" + xSht.Name + ".pdf"

'Check if file already exist
If Len(Dir(xFolder)) > 0 Then
    xYesorNo = MsgBox(xFolder & " already exists." & vbCrLf & vbCrLf & "Do you want to overwrite it?", _
                      vbYesNo + vbQuestion, "File Exists")
    On Error Resume Next
    If xYesorNo = vbYes Then
        Kill xFolder
    Else
        MsgBox "if you don't overwrite the existing PDF, I can't continue." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Exiting Macro"
        Exit Sub
    End If
    If Err.Number <> 0 Then
        MsgBox "Unable to delete existing file.  Please make sure the file is not open or write protected." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Unable to Delete File"
        Exit Sub
    End If
End If

Set xUsedRng = xSht.UsedRange
If Application.WorksheetFunction.CountA(xUsedRng.Cells) <> 0 Then
    'Save as PDF file 
    xSht.ExportAsFixedFormat Type:=xlTypePDF, Filename:=xFolder, Quality:=xlQualityStandard
    
    'Create Outlook email 
    Set xOutlookObj = CreateObject("Outlook.Application")
    Set xEmailObj = xOutlookObj.CreateItem(0)
    With xEmailObj
        .Display
        .To = ""
        .CC = ""
        .Subject = xSht.Name + ".pdf"
        .Attachments.Add xFolder
        If DisplayEmail = False Then
            '.Send
        End If
    End With
Else
  MsgBox "The active worksheet cannot be blank"
  Exit Sub
End If
End Sub

3 กด F5 กุญแจสำคัญในการเรียกใช้รหัส ใน หมวดหมู่สินค้า โปรดเลือกโฟลเดอร์ที่จะบันทึกไฟล์ PDF นี้จากนั้นคลิกที่ไฟล์ OK ปุ่ม

หมายเหตุ : :

บทความที่เกี่ยวข้อง:

• วิธีบันทึกชื่อไฟล์ Excel ด้วยการประทับเวลา?
• วิธีใช้ฟังก์ชัน Save As เพื่อเขียนทับไฟล์ที่มีอยู่ใน Excel โดยอัตโนมัติ
• วิธีบันทึกส่งออกหลายแผ่น / ทั้งหมดเพื่อแยกไฟล์ csv หรือไฟล์ข้อความใน Excel
• จะปิดหรือไม่อนุญาตตัวเลือก Save & Save As ใน Excel ได้อย่างไร
• วิธีปิดการใช้งานสมุดงานบันทึก แต่อนุญาตให้บันทึกเป็นใน Excel เท่านั้น