การเรียนรู้คำสั่ง Nested IF ใน Excel – คำแนะนำทีละขั้นตอน
ใน Excel แม้ว่าฟังก์ชัน IF จำเป็นสำหรับการทดสอบตรรกะขั้นพื้นฐาน แต่เงื่อนไขที่ซับซ้อนมักจะต้องใช้คำสั่ง IF ที่ซ้อนกันเพื่อการประมวลผลข้อมูลที่ได้รับการปรับปรุง ในคู่มือที่ครอบคลุมนี้ เราจะครอบคลุมพื้นฐานของ Nested IF อย่างละเอียด ตั้งแต่ไวยากรณ์ไปจนถึงการใช้งานจริง รวมถึงการผสมผสานของ Nested IF กับเงื่อนไข AND/OR นอกจากนี้ เราจะแบ่งปันวิธีปรับปรุงความสามารถในการอ่านของฟังก์ชัน IF ที่ซ้อนกัน รวมถึงเคล็ดลับบางประการเกี่ยวกับ IF ที่ซ้อนกัน และสำรวจทางเลือกที่มีประสิทธิภาพ เช่น VLOOKUP, IFS และอื่นๆ เพื่อทำให้การดำเนินการทางลอจิคัลที่ซับซ้อนใช้งานง่ายและมีประสิทธิภาพมากขึ้น
- ทำให้ Nested IF อ่านง่าย
- ลำดับของฟังก์ชัน IF ที่ซ้อนกัน
- ตัวเลขและข้อความควรได้รับการปฏิบัติแตกต่างกัน
- ข้อจำกัดของ IF ที่ซ้อนกัน
ฟังก์ชัน Excel IF เทียบกับคำสั่ง Nested IF
ฟังก์ชัน IF และคำสั่ง IF ที่ซ้อนกันใน Excel มีจุดประสงค์คล้ายกัน แต่มีความแตกต่างอย่างมากในด้านความซับซ้อนและการใช้งาน
- ไวยากรณ์คือ:
=IF (logical_test, [value_if_true], [value_if_false]) - การ จำกัด: สามารถจัดการได้ครั้งละหนึ่งเงื่อนไขเท่านั้น ทำให้ไม่เหมาะกับสถานการณ์การตัดสินใจที่ซับซ้อนมากขึ้นซึ่งต้องมีการประเมินหลายเกณฑ์
- ไวยากรณ์คือ:
=IF( condition1, value_if_true1, IF( condition2, value_if_true2, value_if_false2 )) - ความซับซ้อน: สามารถจัดการได้หลายเงื่อนไข แต่อาจซับซ้อนและอ่านยากหากมีการซ้อนกันหลายชั้นเกินไป
การใช้ IF ที่ซ้อนกัน
ส่วนนี้สาธิตการใช้งานพื้นฐานของคำสั่ง IF ที่ซ้อนกันใน Excel รวมถึงไวยากรณ์ ตัวอย่างเชิงปฏิบัติ และวิธีการใช้กับเงื่อนไข AND หรือ OR
ไวยากรณ์ของ IF ที่ซ้อนกัน
การทำความเข้าใจไวยากรณ์ของฟังก์ชันเป็นรากฐานสำหรับการประยุกต์ใช้ฟังก์ชันใน Excel อย่างถูกต้องและมีประสิทธิภาพ เริ่มต้นด้วยไวยากรณ์ของคำสั่ง if ที่ซ้อนกัน
วากยสัมพันธ์:
=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))
ข้อโต้แย้ง:
- Condition1, Condition2, Condition3: These are the conditions you want to test. Each condition is evaluated in order, starting with Condition1.
- Result1: This is the value returned if Condition1 is TRUE.
- Result2: This value is returned if Condition1 is FALSE and Condition2 is TRUE. It's important to note that Result2 is only evaluated if Condition1 is FALSE.
- Result3: This value is returned if both Condition1 and Condition2 are FALSE, and Condition3 is TRUE. Essentially, for Result3 to be evaluated, the previous conditions (Condition1 and Condition2) must both be FALSE.
- Result4: This result is returned if all the conditions (Condition1, Condition2, and Condition3) are FALSE.
In short, this expression can be interpreted as follows:Test condition1, if TRUE, return result1, if FALSE,
test condition2, if TRUE, return result2, if FALSE,
test condition3, if TRUE, return result3, if FALSE,
return result4
โปรดจำไว้ว่า ในโครงสร้าง IF ที่ซ้อนกัน แต่ละเงื่อนไขที่ตามมาจะได้รับการประเมินก็ต่อเมื่อเงื่อนไขก่อนหน้านี้ทั้งหมดเป็น FALSE การตรวจสอบตามลำดับนี้มีความสำคัญอย่างยิ่งต่อการทำความเข้าใจวิธีการทำงานของ IF ที่ซ้อนกัน
ตัวอย่างการใช้งานจริงของ Nested IF
ตอนนี้ เรามาเจาะลึกการใช้ IF แบบซ้อนกันพร้อมตัวอย่างเชิงปฏิบัติสองตัวอย่าง
ตัวอย่างที่ 1: ระบบการให้เกรด
ดังที่แสดงในภาพหน้าจอด้านล่าง สมมติว่าคุณมีรายการคะแนนของนักเรียนและต้องการให้คะแนนตามคะแนนเหล่านี้ คุณสามารถใช้ IF แบบซ้อนเพื่อทำงานนี้ให้สำเร็จได้
เลือกเซลล์ว่าง (C2 ในกรณีนี้) ป้อนสูตรต่อไปนี้แล้วกด เข้าสู่ เพื่อให้ได้ผลลัพธ์ จากนั้นลาก เติมที่จับ ลงเพื่อให้ได้ผลลัพธ์ที่เหลือ
=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))- คุณสามารถระบุระดับเกรดในสูตรได้โดยตรง ดังนั้นจึงสามารถเปลี่ยนสูตรเป็น:
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F")))) - สูตรนี้ใช้เพื่อกำหนดเกรด (A, B, C, D หรือ F) ตามคะแนนในเซลล์ A2 โดยใช้เกณฑ์การให้เกรดมาตรฐาน เป็นกรณีการใช้งานทั่วไปสำหรับคำสั่ง IF ที่ซ้อนกันในระบบการให้เกรดทางวิชาการ
- คำอธิบายของสูตร:
- A2>=90: นี่เป็นเงื่อนไขแรกที่ตรวจสอบสูตร ถ้าคะแนนในเซลล์ A2 มากกว่าหรือเท่ากับ 90 สูตรจะส่งกลับ "A"
- A2>=80: หากเงื่อนไขแรกเป็นเท็จ (คะแนนน้อยกว่า 90) จะตรวจสอบว่า A2 มากกว่าหรือเท่ากับ 80 หากเป็นจริง จะส่งกลับ "B"
- A2>=70: ในทำนองเดียวกัน หากคะแนนน้อยกว่า 80 จะตรวจสอบว่ามากกว่าหรือเท่ากับ 70 หากเป็นจริง จะส่งกลับ "C"
- A2>=60: ถ้าคะแนนน้อยกว่า 70 สูตรจะตรวจสอบว่ามากกว่าหรือเท่ากับ 60 ถ้าเป็นจริง จะส่งกลับ "D"
- "F": สุดท้ายนี้ หากไม่ตรงตามเงื่อนไขข้างต้น (หมายถึงคะแนนน้อยกว่า 60) สูตรจะส่งกลับ "F"
ตัวอย่างที่ 2: การคำนวณค่าคอมมิชชั่นการขาย
ลองนึกภาพสถานการณ์ที่ตัวแทนฝ่ายขายได้รับอัตราค่าคอมมิชชันที่แตกต่างกันตามความสำเร็จในการขาย ดังที่แสดงในภาพหน้าจอด้านล่าง คุณต้องการคำนวณค่าคอมมิชชันของพนักงานขายตามเกณฑ์การขายที่แตกต่างกันเหล่านี้ และคำสั่ง IF ที่ซ้อนกันสามารถช่วยคุณได้
- 20% สำหรับยอดขายที่สูงกว่า 20,000 ดอลลาร์
- 15% สำหรับการขายระหว่าง 10,000 ถึง 20,000 เหรียญสหรัฐ
- 10% สำหรับยอดขายต่ำกว่า 10,000 ดอลลาร์
เลือกเซลล์ว่าง (C2 ในกรณีนี้) ป้อนสูตรต่อไปนี้แล้วกด เข้าสู่ เพื่อให้ได้ผลลัพธ์ จากนั้นลาก เติมที่จับ ลงเพื่อให้ได้ผลลัพธ์ที่เหลือ
=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))
- คุณสามารถระบุอัตราค่าคอมมิชชันได้โดยตรงในสูตร ดังนั้นสูตรจึงสามารถเปลี่ยนเป็น:
=B2*IF(B2>20000, 20%, IF(B2>=10000, 15%, 10%)) - สูตรที่ให้ไว้ใช้ในการคำนวณค่าคอมมิชชันของพนักงานขายตามยอดขาย โดยใช้อัตราค่าคอมมิชชันที่แตกต่างกันสำหรับเกณฑ์การขายที่แตกต่างกัน
- คำอธิบายของสูตร:
- B2: นี่แสดงถึงยอดขายของพนักงานขาย ซึ่งใช้เป็นฐานในการคำนวณค่าคอมมิชชั่น
- ถ้า(B2>20000, "20%", ...): นี่เป็นเงื่อนไขแรกที่ตรวจสอบ ตรวจสอบว่ายอดขายใน B2 มากกว่า 20,000 หรือไม่ หากเป็นเช่นนั้น สูตรจะใช้อัตราค่าคอมมิชชัน 20%
- ถ้า(B2>=10000, "15%", "10%"): หากเงื่อนไขแรกเป็นเท็จ (ยอดขายไม่เกิน 20,000) สูตรจะตรวจสอบว่ายอดขายเท่ากับหรือมากกว่า 10,000 หรือไม่ หากเป็นจริง จะใช้อัตราค่าคอมมิชชั่น 15% หากยอดขายน้อยกว่า 10,000 สูตรจะมีค่าเริ่มต้นอยู่ที่อัตราค่าคอมมิชชัน 10%
ซ้อนกันหากมีเงื่อนไข AND / OR
ในส่วนนี้ ฉันแก้ไขตัวอย่างแรกข้างต้น "ระบบการให้เกรด" เพื่อสาธิตวิธีรวมเงื่อนไข IF ที่ซ้อนกันเข้ากับเงื่อนไข AND หรือ OR ใน Excel ในตัวอย่างการให้เกรดที่แก้ไข ฉันได้แนะนำเงื่อนไขเพิ่มเติมโดยยึดตาม "อัตราการเข้าร่วม"
การใช้ Nested หากมีเงื่อนไข AND
หากนักเรียนมีคุณสมบัติตรงตามทั้งคะแนนและเกณฑ์การเข้าชั้นเรียน พวกเขาจะได้รับการเพิ่มเกรด ตัวอย่างเช่น นักเรียนที่มีคะแนน 60 ขึ้นไปและมีอัตราการเข้าเรียน 95% ขึ้นไป จะได้รับการอัปเกรดเกรดขึ้นหนึ่งระดับ เช่น จาก A เป็น A+, B เป็น B+ และอื่นๆ อย่างไรก็ตาม หากอัตราการเข้าเรียนต่ำกว่า 95% การให้เกรดจะเป็นไปตามเกณฑ์คะแนนเดิม ในกรณีเช่นนี้ เราจำเป็นต้องใช้คำสั่ง IF ที่ซ้อนกันโดยมีเงื่อนไข AND
เลือกเซลล์ว่าง (D2 ในกรณีนี้) ป้อนสูตรต่อไปนี้แล้วกด เข้าสู่ เพื่อให้ได้ผลลัพธ์ จากนั้นลาก เติมที่จับ ลงเพื่อให้ได้ผลลัพธ์ที่เหลือ
=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))
- และตรวจเช็คสภาพ:
และ(B2>=60, C2>=95%): เงื่อนไข AND จะตรวจสอบก่อนว่าตรงตามเงื่อนไขทั้งสองหรือไม่ — คะแนนของนักเรียนคือ 60 หรือสูงกว่า และอัตราการเข้าเรียนคือ 95% ขึ้นไป - การมอบหมายเกรดใหม่:
IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))): ถ้าทั้งสองเงื่อนไขในคำสั่ง AND เป็นจริง สูตรจะตรวจสอบคะแนนของนักเรียนและเพิ่มเกรดขึ้นหนึ่งระดับ- B2>=90: หากคะแนนตั้งแต่ 90 ขึ้นไป ถือว่าได้เกรด "A"+".การมอบหมายเกรดใหม่:
- B2>=80: หากคะแนนตั้งแต่ 80 ขึ้นไป (แต่น้อยกว่า 90) ให้เกรดเป็น "B"+".
- B2>=70: หากคะแนนตั้งแต่ 70 ขึ้นไป (แต่น้อยกว่า 80) ถือว่าเกรดเป็น "C+"
- B2>=60: หากคะแนนตั้งแต่ 60 ขึ้นไป (แต่น้อยกว่า 70) เกรดจะเป็น "D+"
- การมอบหมายเกรดปกติ:
IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))) ): ถ้าไม่ตรงตามเงื่อนไข AND (คะแนนต่ำกว่า 80 หรือการเข้าเรียนต่ำกว่า 95%) สูตรจะกำหนดเกรดมาตรฐาน- B2>=90: คะแนน 90 ขึ้นไปจะได้รับ "A"
- B2>=80: คะแนน 80 ขึ้นไป (แต่น้อยกว่า 90) จะได้รับ "B"
- B2>=70: คะแนน 70 ขึ้นไป (แต่น้อยกว่า 80) จะได้รับ "C"
- B2>=60: คะแนน 60 ขึ้นไป (แต่น้อยกว่า 70) จะได้รับ "D"
- คะแนนต่ำกว่า 60 จะได้รับ "F"
การใช้ Nested หากมีเงื่อนไข OR
ในกรณีนี้ คะแนนของนักเรียนจะเพิ่มขึ้นหนึ่งระดับหากคะแนนคือ 95 ขึ้นไป หรือหากอัตราการเข้าเรียนคือ 95% ขึ้นไป ต่อไปนี้คือวิธีที่เราสามารถทำได้โดยใช้เงื่อนไข IF และ OR ที่ซ้อนกัน
เลือกเซลล์ว่าง (D2 ในกรณีนี้) ป้อนสูตรต่อไปนี้แล้วกด เข้าสู่ เพื่อให้ได้ผลลัพธ์ จากนั้นลาก เติมที่จับ ลงเพื่อให้ได้ผลลัพธ์ที่เหลือ
=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))
- หรือการตรวจสอบสภาพ:
หรือ(B2>=95, C2>=95%): สูตรจะตรวจสอบก่อนว่าเงื่อนไขข้อใดข้อหนึ่งเป็นจริงหรือไม่ — คะแนนของนักเรียนคือ 95 หรือสูงกว่า หรืออัตราการเข้าเรียนคือ 95% หรือสูงกว่า - การมอบหมายเกรดพร้อมโบนัส:
IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+"))) ): หากเงื่อนไขข้อใดข้อหนึ่งในคำสั่ง OR เป็นจริง คะแนนของนักเรียนจะเพิ่มขึ้นหนึ่งระดับ- B2>=90: หากคะแนนตั้งแต่ 90 ขึ้นไป ถือว่าได้เกรด "A+"
- B2>=80: หากคะแนนตั้งแต่ 80 ขึ้นไป (แต่น้อยกว่า 90) ถือว่าเกรดเป็น "B+"
- B2>=70: หากคะแนนตั้งแต่ 70 ขึ้นไป (แต่น้อยกว่า 80) ถือว่าเกรดเป็น "C+"
- B2>=60: หากคะแนนตั้งแต่ 60 ขึ้นไป (แต่น้อยกว่า 70) ถือว่าเกรดเป็น "D+"
- มิฉะนั้นเกรดจะเป็น "F+"
- การมอบหมายเกรดปกติ:
IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))): หากไม่ตรงตามเงื่อนไข OR ทั้งสองข้อ (คะแนนต่ำกว่า 95 และการเข้าชั้นเรียนต่ำกว่า 95%) สูตรจะกำหนดเกรดมาตรฐาน- B2>=90: คะแนน 90 ขึ้นไปจะได้รับ "A"
- B2>=80: คะแนน 80 ขึ้นไป (แต่น้อยกว่า 90) จะได้รับ "B"
- B2>=70: คะแนน 70 ขึ้นไป (แต่น้อยกว่า 80) จะได้รับ "C"
- B2>=60: คะแนน 60 ขึ้นไป (แต่น้อยกว่า 70) จะได้รับ "D"
- คะแนนต่ำกว่า 60 จะได้รับ "F"
เคล็ดลับและคำแนะนำสำหรับ Nested IF
ส่วนนี้ครอบคลุมถึงเคล็ดลับและคำแนะนำที่เป็นประโยชน์สี่ประการสำหรับ Nested IF
ทำให้ Nested IF อ่านง่าย
คำสั่ง IF ที่ซ้อนกันโดยทั่วไปอาจดูกะทัดรัดแต่สามารถถอดรหัสได้ยาก
ในสูตรต่อไปนี้ การระบุอย่างรวดเร็วว่าเงื่อนไขหนึ่งสิ้นสุดที่ใดและอีกเงื่อนไขหนึ่งเริ่มต้นอย่างรวดเร็ว เป็นเรื่องท้าทาย โดยเฉพาะอย่างยิ่งเมื่อความซับซ้อนเพิ่มขึ้น
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))วิธีแก้ปัญหา: การเพิ่มตัวแบ่งบรรทัดและการเยื้อง
หากต้องการให้ IF ที่ซ้อนกันอ่านง่าย คุณสามารถแบ่งสูตรออกเป็นหลายบรรทัด โดยให้แต่ละ IF ที่ซ้อนกันอยู่บนบรรทัดใหม่ ในสูตร เพียงวางเคอร์เซอร์ไว้หน้า IF แล้วกดปุ่ม Alt + Enter
หลังจากแตกสูตรข้างต้นแล้วจะแสดงผลดังนี้:
=IF(A2>=90, "A",
IF(A2>=80, "B",
IF(A2>=70, "C",
IF(A2>=60, "D", "F")))
)รูปแบบนี้ทำให้ชัดเจนยิ่งขึ้นว่าแต่ละเงื่อนไขและเอาต์พุตที่สอดคล้องกันอยู่ที่ใด ช่วยเพิ่มความสามารถในการอ่านของสูตร
ลำดับของฟังก์ชัน IF ที่ซ้อนกัน
ลำดับของเงื่อนไขทางลอจิคัลในสูตร IF ที่ซ้อนกันเป็นสิ่งสำคัญ เนื่องจากจะกำหนดวิธีที่ Excel ประเมินเงื่อนไขเหล่านี้ และส่งผลต่อผลลัพธ์สุดท้ายของสูตร
สูตรที่ถูกต้อง
ในตัวอย่างระบบการให้เกรด เราใช้สูตรต่อไปนี้เพื่อกำหนดเกรดตามคะแนน
=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))
Excel จะประเมินเงื่อนไขในสูตร IF ที่ซ้อนกันตามลำดับ ตั้งแต่เงื่อนไขแรกไปจนถึงเงื่อนไขสุดท้าย สูตรนี้จะตรวจสอบเกณฑ์คะแนนสูงสุดก่อน (>=90 สำหรับ "A") จากนั้นจึงย้ายไปยังเกณฑ์ที่ต่ำกว่า ช่วยให้มั่นใจได้ว่าคะแนนจะถูกเปรียบเทียบกับเกรดสูงสุดที่มีคุณสมบัติ หากเงื่อนไขแรกเป็นจริง (A2>=90) จะส่งกลับ "A" และจะไม่ประเมินเงื่อนไขใดๆ เพิ่มเติม
สูตรการสั่งไม่ถูกต้อง
ถ้าลำดับของเงื่อนไขถูกย้อนกลับ โดยเริ่มจากเกณฑ์ต่ำสุด จะส่งกลับผลลัพธ์ที่ไม่ถูกต้อง
=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))
ในสูตรที่ไม่ถูกต้องนี้ คะแนน 95 จะตรงตามเงื่อนไขแรก B2>=60 ทันที และกำหนดให้เกรด "D" ไม่ถูกต้อง
ตัวเลขและข้อความควรได้รับการปฏิบัติแตกต่างกัน
ส่วนนี้จะแสดงให้คุณเห็นว่าตัวเลขและข้อความได้รับการปฏิบัติแตกต่างกันอย่างไรในคำสั่ง IF ที่ซ้อนกัน
เบอร์
ตัวเลขใช้สำหรับการเปรียบเทียบและการคำนวณทางคณิตศาสตร์ ในคำสั่ง IF ที่ซ้อนกัน คุณสามารถเปรียบเทียบตัวเลขได้โดยตรงโดยใช้ตัวดำเนินการ เช่น >, <, =, >= และ <=
ข้อความ
ในคำสั่ง IF ที่ซ้อนกัน ข้อความควรเป็น อยู่ในเครื่องหมายคำพูดคู่. ดู A, B, C ,D และ F ในสูตรต่อไปนี้:
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))ข้อจำกัดของ IF ที่ซ้อนกัน
ส่วนนี้แสดงรายการข้อจำกัดและข้อเสียหลายประการของ IF ที่ซ้อนกัน
ความซับซ้อนและความสามารถในการอ่าน:
แม้ว่า Excel จะให้คุณซ้อนฟังก์ชัน IF ได้ถึง 64 ฟังก์ชัน แต่ก็ไม่แนะนำให้ทำเช่นนั้นเลย ยิ่งระดับการซ้อนมากเท่าไร สูตรก็จะยิ่งซับซ้อนมากขึ้นเท่านั้น ซึ่งอาจนำไปสู่สูตรที่อ่าน ทำความเข้าใจ และบำรุงรักษาได้ยาก
ข้อผิดพลาดง่าย:
นอกจากนี้ คำสั่ง IF ที่ซ้อนกันแบบซับซ้อนอาจมีแนวโน้มที่จะเกิดข้อผิดพลาดและท้าทายในการแก้ไขหรือแก้ไข
ขยายหรือปรับขนาดได้ยาก:
หากตรรกะของคุณเปลี่ยนแปลงหรือคุณต้องการเพิ่มเงื่อนไข IF ที่ซ้อนกันแบบลึกอาจแก้ไขหรือขยายได้ยาก
การทำความเข้าใจข้อจำกัดเหล่านี้เป็นกุญแจสำคัญในการใช้คำสั่ง IF ที่ซ้อนกันใน Excel อย่างมีประสิทธิภาพ บ่อยครั้ง การรวม IF ที่ซ้อนกันเข้ากับฟังก์ชันอื่นๆ หรือการมองหาแนวทางอื่นสามารถนำไปสู่โซลูชันที่มีประสิทธิภาพและบำรุงรักษาได้มากขึ้น
ทางเลือกแทน Nested IF
ส่วนนี้แสดงรายการฟังก์ชันต่างๆ ใน Excel ที่สามารถใช้เป็นทางเลือกแทนคำสั่ง IF ที่ซ้อนกันได้
การใช้ VLOOKUP
คุณสามารถใช้ฟังก์ชัน VLOOKUP แทนคำสั่ง IF ที่ซ้อนกัน เพื่อทำตัวอย่างในทางปฏิบัติสองตัวอย่างข้างต้นได้ ต่อไปนี้คือวิธีที่คุณสามารถทำได้:
ตัวอย่างที่ 1: ระบบการให้เกรดด้วย VLOOKUP
ที่นี่ฉันจะแสดงวิธีใช้ VLOOKUP เพื่อให้คะแนนตามคะแนน
ขั้นตอนที่ 1: สร้างตารางค้นหาสำหรับเกรด
ขั้นแรก คุณต้องสร้างตารางค้นหา (เช่น E1:F6 ในกรณีนี้) สำหรับช่วงคะแนนและเกรดที่เกี่ยวข้อง หมายเหตุ: คะแนนในคอลัมน์แรกของตารางจะต้องเรียงลำดับจากน้อยไปหามาก
ขั้นตอนที่ 2: ใช้ฟังก์ชัน VLOOKUP เพื่อกำหนดเกรด
เลือกเซลล์ว่าง (ในกรณีนี้คือ C2) ป้อนสูตรต่อไปนี้แล้วกดปุ่ม เข้าสู่ กุญแจสำคัญในการเข้าเรียนชั้นประถมศึกษาปีที่ 1 เลือกเซลล์สูตรนี้แล้วลาก เติมที่จับ ลงไปรับเกรดที่เหลือ
=VLOOKUP(B2,$E$2:$F$6,2,TRUE)
- ค่า 95 ในเซลล์ B2 คือสิ่งที่ VLOOKUP ค้นหาในคอลัมน์แรกของตารางการค้นหา ($E$2:$F$6) หากพบ ระบบจะส่งกลับเกรดที่เกี่ยวข้องจากคอลัมน์ที่สองของตาราง ซึ่งอยู่ในแถวเดียวกันกับค่าที่ตรงกัน
- อย่าลืมทำให้การอ้างอิงตารางการค้นหาเป็นแบบสัมบูรณ์ (เพิ่มเครื่องหมายดอลลาร์ ($) ก่อนการอ้างอิง) ซึ่งหมายความว่าการอ้างอิงจะไม่เปลี่ยนแปลงหากคัดลอกสูตรไปยังเซลล์อื่น
- หากต้องการทราบข้อมูลเพิ่มเติมเกี่ยวกับฟังก์ชัน VLOOKUP เยี่ยมชมหน้านี้.
ตัวอย่างที่ 2: การคำนวณค่าคอมมิชชันการขายด้วย VLOOKUP
คุณยังสามารถใช้ VLOOKUP เพื่อคำนวณค่าคอมมิชชันการขายใน Excel ได้สำเร็จ กรุณาทำดังนี้.
ขั้นตอนที่ 1: สร้างตารางค้นหาสำหรับเกรด
ขั้นแรก คุณต้องสร้างตารางค้นหาสำหรับยอดขายและอัตราค่าคอมมิชชั่นที่เกี่ยวข้อง เช่น E2:F4 ในกรณีนี้ หมายเหตุ: ยอดขายในคอลัมน์แรกของตารางจะต้องเรียงลำดับจากน้อยไปหามาก
ขั้นตอนที่ 2: ใช้ฟังก์ชัน VLOOKUP เพื่อกำหนดเกรด
เลือกเซลล์ว่าง (C2 ในกรณีนี้) ป้อนสูตรต่อไปนี้แล้วกดปุ่ม Enter เพื่อรับคอมมิชชั่นแรก เลือกเซลล์สูตรนี้แล้วลาก Fill Handle ลงเพื่อให้ได้ผลลัพธ์ที่เหลือ
=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)
- ในทั้งสองตัวอย่าง VLOOKUP ใช้เพื่อค้นหาค่าในตารางตามค่าการค้นหา (คะแนนหรือยอดขาย) และส่งกลับค่าในแถวเดียวกันจากคอลัมน์ที่ระบุ (เกรดหรืออัตราค่าคอมมิชชัน) พารามิเตอร์ที่สี่ TRUE ระบุการจับคู่โดยประมาณ ซึ่งเหมาะสำหรับสถานการณ์เหล่านี้ซึ่งอาจไม่มีค่าการค้นหาที่ตรงกันทุกประการในตาราง
- หากต้องการทราบข้อมูลเพิ่มเติมเกี่ยวกับฟังก์ชัน VLOOKUP เยี่ยมชมหน้านี้.
การใช้ไอเอฟเอส
พื้นที่ ฟังก์ชันไอเอฟเอส ลดความซับซ้อนของกระบวนการโดยขจัดความจำเป็นในการซ้อนและทำให้สูตรอ่านและจัดการได้ง่ายขึ้น ช่วยเพิ่มความสามารถในการอ่านและปรับปรุงการจัดการการตรวจสอบแบบมีเงื่อนไขหลายรายการ หากต้องการใช้ฟังก์ชัน IFS ตรวจสอบให้แน่ใจว่าคุณใช้ Excel 2019 หรือใหม่กว่า หรือมีการสมัครใช้งาน Office 365 เรามาดูกันว่าจะสามารถนำไปใช้ได้อย่างไรในตัวอย่างเชิงปฏิบัติ
ตัวอย่างที่ 1: ระบบการให้เกรดด้วย IFS
สมมติว่าเกณฑ์การให้เกรดเหมือนเดิม ฟังก์ชัน IFS สามารถใช้ได้ดังนี้:
เลือกเซลล์ว่าง เช่น C2 ป้อนสูตรต่อไปนี้แล้วกด เข้าสู่ เพื่อให้ได้ผลลัพธ์แรก เลือกเซลล์ผลลัพธ์นี้แล้วลาก เติมที่จับ ลงเพื่อให้ได้ผลลัพธ์ที่เหลือ
=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")
- แต่ละเงื่อนไขได้รับการประเมินตามลำดับ ทันทีที่ตรงตามเงื่อนไข ผลลัพธ์ที่เกี่ยวข้องจะถูกส่งกลับ และสูตรจะหยุดตรวจสอบเงื่อนไขเพิ่มเติม ในกรณีนี้ สูตรจะใช้เพื่อกำหนดเกรดตามคะแนนใน B2 ตามระดับการให้เกรดทั่วไปซึ่งคะแนนที่สูงกว่าจะสอดคล้องกับเกรดที่ดีกว่า
- หากต้องการทราบข้อมูลเพิ่มเติมเกี่ยวกับฟังก์ชัน IFS เยี่ยมชมหน้านี้.
ตัวอย่างที่ 2: การคำนวณค่าคอมมิชชั่นการขายด้วย IFS
สำหรับสถานการณ์การคำนวณค่าคอมมิชชันการขาย ฟังก์ชัน IFS จะถูกนำไปใช้ดังต่อไปนี้:
เลือกเซลล์ว่าง เช่น C2 ป้อนสูตรต่อไปนี้แล้วกด เข้าสู่ เพื่อให้ได้ผลลัพธ์แรก เลือกเซลล์ผลลัพธ์นี้แล้วลาก เติมที่จับ ลงเพื่อให้ได้ผลลัพธ์ที่เหลือ
=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)
การใช้การเลือกและการจับคู่
แนวทาง CHOOSE และ MATCH มีประสิทธิภาพมากกว่าและจัดการได้ง่ายกว่าเมื่อเทียบกับคำสั่ง IF ที่ซ้อนกัน วิธีนี้จะช่วยลดความซับซ้อนของสูตรและทำให้การอัปเดตหรือการเปลี่ยนแปลงตรงไปตรงมามากขึ้น ด้านล่างนี้ ผมจะสาธิตวิธีใช้ฟังก์ชัน CHOOSE และ MATCH ร่วมกันเพื่อจัดการกับตัวอย่างที่เป็นประโยชน์ 2 ตัวอย่างในบทความนี้
ตัวอย่างที่ 1: ระบบการให้เกรดด้วย CHOOSE และ MATCH
คุณสามารถใช้ฟังก์ชัน CHOOSE และ MATCH ร่วมกันเพื่อกำหนดเกรดตามคะแนนที่ต่างกันได้
ขั้นตอนที่ 1: สร้างอาร์เรย์การค้นหาด้วยค่าการค้นหา
ขั้นแรก คุณต้องสร้างช่วงของเซลล์ที่มีค่าเกณฑ์ที่ MATCH จะค้นหา เช่น $E$2:$E$6 ในกรณีนี้ หมายเหตุ: ตัวเลขในช่วงนี้ต้องเรียงลำดับจากน้อยไปหามากเพื่อให้ฟังก์ชัน MATCH ทำงานได้อย่างถูกต้องเมื่อใช้ประเภทการจับคู่โดยประมาณ
ขั้นตอนที่ 2: ใช้ CHOOSE และ MATCH เพื่อกำหนดเกรด
เลือกเซลล์ว่าง (ในกรณีนี้คือ C2) ป้อนสูตรต่อไปนี้แล้วกดปุ่ม เข้าสู่ กุญแจสำคัญในการเข้าเรียนชั้นประถมศึกษาปีที่ 1 เลือกเซลล์สูตรนี้แล้วลาก เติมที่จับ ลงเพื่อให้ได้ผลลัพธ์ที่เหลือ
=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")
- แมตช์(B2, $E$2:$E$6, 1): ส่วนนี้ของสูตรค้นหาคะแนน (95) ในเซลล์ B2 ภายในช่วง $E$2:$E$6 เลข 1 บ่งชี้ว่า MATCH ควรค้นหาค่าที่ตรงกันโดยประมาณ ซึ่งหมายความว่าจะหาค่าที่มากที่สุดในช่วงที่น้อยกว่าหรือเท่ากับ B2
- เลือก(..., "F", "D", "C", "B", "A"): ขึ้นอยู่กับตำแหน่งที่ส่งคืนโดยฟังก์ชัน MATCH CHOOSE จะเลือกเกรดที่เกี่ยวข้อง
- หากต้องการทราบข้อมูลเพิ่มเติมเกี่ยวกับไฟล์ ฟังก์ชัน MATCH, เยี่ยมชมหน้านี้.
- หากต้องการทราบข้อมูลเพิ่มเติมเกี่ยวกับไฟล์ เลือกฟังก์ชั่น, เยี่ยมชมหน้านี้.
ตัวอย่างที่ 2: การคำนวณค่าคอมมิชชั่นการขายด้วย IFS
การใช้ชุดค่าคอมมิชชัน CHOOSE และ MATCH สำหรับการคำนวณค่าคอมมิชชั่นการขายก็อาจมีประสิทธิภาพเช่นกัน โดยเฉพาะอย่างยิ่งเมื่ออัตราค่าคอมมิชชั่นขึ้นอยู่กับเกณฑ์การขายที่ระบุ มาดูกันว่าเราทำได้อย่างไร
ขั้นตอนที่ 1: สร้างอาร์เรย์การค้นหาด้วยค่าการค้นหา
ขั้นแรก คุณต้องสร้างช่วงของเซลล์ที่มีค่าเกณฑ์ที่ MATCH จะค้นหา เช่น $E$2:$E$4 ในกรณีนี้ หมายเหตุ: ตัวเลขในช่วงนี้ต้องเรียงลำดับจากน้อยไปหามากเพื่อให้ฟังก์ชัน MATCH ทำงานได้อย่างถูกต้องเมื่อใช้ประเภทการจับคู่โดยประมาณ
ขั้นตอนที่ 2: ใช้ CHOOSE และ MATCH เพื่อให้ได้ผลลัพธ์
เลือกเซลล์ว่าง (ในกรณีนี้คือ C2) ป้อนสูตรต่อไปนี้แล้วกดปุ่ม เข้าสู่ กุญแจสำคัญในการเข้าเรียนชั้นประถมศึกษาปีที่ 1 เลือกเซลล์สูตรนี้แล้วลาก เติมที่จับ ลงเพื่อให้ได้ผลลัพธ์ที่เหลือ
=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)
- หากต้องการทราบข้อมูลเพิ่มเติมเกี่ยวกับไฟล์ ฟังก์ชัน MATCH, เยี่ยมชมหน้านี้.
- หากต้องการทราบข้อมูลเพิ่มเติมเกี่ยวกับไฟล์ เลือกฟังก์ชั่น, เยี่ยมชมหน้านี้.
โดยสรุป การเรียนรู้คำสั่ง IF ที่ซ้อนกันใน Excel เป็นทักษะอันทรงคุณค่าที่ช่วยเพิ่มความสามารถของคุณในการจัดการสถานการณ์ลอจิคัลที่ซับซ้อนในการวิเคราะห์ข้อมูลและกระบวนการตัดสินใจ แม้ว่า IF ที่ซ้อนกันจะมีประสิทธิภาพสำหรับการดำเนินการเชิงตรรกะที่ซับซ้อน แต่สิ่งสำคัญคือต้องคำนึงถึงข้อจำกัดต่างๆ ทางเลือกที่ง่ายกว่า เช่น VLOOKUP, IFS และ CHOOSE ที่มี MATCH สามารถมอบโซลูชันที่มีประสิทธิภาพมากขึ้นในบางสถานการณ์ ด้วยข้อมูลเชิงลึกเหล่านี้ ตอนนี้คุณสามารถใช้เทคนิค Excel ที่เหมาะสมที่สุดกับงานการวิเคราะห์ข้อมูลของคุณได้อย่างมั่นใจ มั่นใจได้ถึงความชัดเจน ความถูกต้อง และมีประสิทธิภาพในสเปรดชีตของคุณ สำหรับผู้ที่ต้องการเจาะลึกถึงความสามารถของ Excel เว็บไซต์ของเรามีบทช่วยสอนมากมาย ค้นพบเคล็ดลับและคำแนะนำเพิ่มเติมเกี่ยวกับ Excel ที่นี่.
สุดยอดเครื่องมือเพิ่มผลผลิตในสำนักงาน
เพิ่มพูนทักษะ Excel ของคุณด้วย Kutools สำหรับ Excel และสัมผัสประสิทธิภาพอย่างที่ไม่เคยมีมาก่อน Kutools สำหรับ Excel เสนอคุณสมบัติขั้นสูงมากกว่า 300 รายการเพื่อเพิ่มประสิทธิภาพและประหยัดเวลา คลิกที่นี่เพื่อรับคุณสมบัติที่คุณต้องการมากที่สุด...
แท็บ Office นำอินเทอร์เฟซแบบแท็บมาที่ Office และทำให้งานของคุณง่ายขึ้นมาก
- เปิดใช้งานการแก้ไขและอ่านแบบแท็บใน Word, Excel, PowerPoint, ผู้จัดพิมพ์, Access, Visio และโครงการ
- เปิดและสร้างเอกสารหลายรายการในแท็บใหม่ของหน้าต่างเดียวกันแทนที่จะเป็นในหน้าต่างใหม่
- เพิ่มประสิทธิภาพการทำงานของคุณ 50% และลดการคลิกเมาส์หลายร้อยครั้งให้คุณทุกวัน!
สารบัญ
- ฟังก์ชัน IF กับคำสั่ง IF ที่ซ้อนกัน
- การใช้ IF ที่ซ้อนกัน
- ไวยากรณ์ของ IF ที่ซ้อนกัน
- ตัวอย่างการใช้งานจริงของ Nested IF
- ซ้อนกันหากมีเงื่อนไข AND / OR
- เคล็ดลับและคำแนะนำสำหรับ Nested IF
- ทำให้ Nested IF อ่านง่าย
- ลำดับของฟังก์ชัน IF ที่ซ้อนกัน
- ตัวเลขและข้อความควรได้รับการปฏิบัติแตกต่างกัน
- ข้อจำกัดของ IF ที่ซ้อนกัน
- ทางเลือกแทน Nested IF
- การใช้ VLOOKUP
- การใช้ไอเอฟเอส
- การใช้การเลือกและการจับคู่
- บทความที่เกี่ยวข้อง
- เครื่องมือเพิ่มประสิทธิภาพการทำงานในสำนักงานที่ดีที่สุด
- ความคิดเห็น