จะย้ายไฟล์เฉพาะจากโฟลเดอร์หนึ่งไปยังอีกโฟลเดอร์หนึ่งใน Excel ได้อย่างไร?

สมมติว่าฉันมีโฟลเดอร์ขนาดใหญ่ซึ่งมีไฟล์หลายประเภทเช่น docx, jpg, xlsx เป็นต้นตามภาพหน้าจอต่อไปนี้ ตอนนี้ฉันต้องการย้ายไฟล์บางประเภทจากโฟลเดอร์ไปยังโฟลเดอร์ใหม่โดยไม่ต้องย้ายทีละไฟล์ด้วยตนเอง คุณมีความคิดที่ดีในการแก้ปัญหานี้ใน Excel หรือไม่?

ย้ายไฟล์เฉพาะจากโฟลเดอร์หนึ่งไปยังโฟลเดอร์อื่นด้วยรหัส VBA

ย้ายไฟล์เฉพาะจากโฟลเดอร์หนึ่งไปยังโฟลเดอร์อื่นด้วยรหัส VBA

หากต้องการย้ายไฟล์บางประเภทจากโฟลเดอร์หนึ่งไปยังอีกโฟลเดอร์หนึ่งโดยเร็วที่สุดเท่าที่คุณต้องการรหัส VBA ต่อไปนี้อาจช่วยคุณได้โปรดดำเนินการดังนี้:

1. กดค้างไว้ ALT + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2. คลิก สิ่งที่ใส่เข้าไป > โมดูลและวางรหัสต่อไปนี้ในไฟล์ โมดูล หน้าต่าง.

รหัส VBA: ย้ายไฟล์บางประเภทจากโฟลเดอร์หนึ่งไปยังอีกโฟลเดอร์หนึ่ง:

Sub MoveFiles()
'Updateby Extendoffice
    Dim xFd As FileDialog
    Dim xTFile As String
    Dim xExtArr As Variant
    Dim xExt As Variant
    Dim xSPath As String
    Dim xDPath As String
    Dim xSFile As String
    Dim xCount As Long
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    xFd.Title = "Please select the original folder:"
    If xFd.Show = -1 Then
        xSPath = xFd.SelectedItems(1)
    Else
        Exit Sub
    End If
    If Right(xSPath, 1) <> "\" Then xSPath = xSPath + "\"
    xFd.Title = "Please select the destination folder:"
    If xFd.Show = -1 Then
        xDPath = xFd.SelectedItems(1)
    Else
        Exit Sub
    End If
    If Right(xDPath, 1) <> "\" Then xDPath = xDPath + "\"
    xExtArr = Array("*.xlsx*", "*.jpg")
    For Each xExt In xExtArr
        xTFile = Dir(xSPath & xExt)
        Do While xTFile <> ""
            xSFile = xSPath & xTFile
            FileCopy xSFile, xDPath & xTFile
            Kill xSFile
            xTFile = Dir
            xCount = xCount + 1
        Loop
    Next
    MsgBox "Total number of moved files is: " & xCount, vbInformation, "Kutools for Excel"
End Sub

หมายเหตุ: ในโค้ดด้านบน "* .xlsx *""* .jpg"ในสคริปต์: xExtArr = อาร์เรย์ ("*. xlsx *", "* .jpg") เป็นประเภทไฟล์ที่คุณต้องการย้ายคุณสามารถเปลี่ยนเป็นประเภทอื่นหรือเพิ่มประเภทไฟล์อื่น ๆ ได้ตามต้องการ

3. จากนั้นกด F5 คีย์เพื่อเรียกใช้รหัสนี้และหน้าต่างจะโผล่ขึ้นมาเพื่อเตือนให้คุณเลือกโฟลเดอร์เดิมที่คุณต้องการย้ายไฟล์ดูภาพหน้าจอ:

4. จากนั้นคลิก OKและมีหน้าต่างอื่นโผล่ขึ้นมาโปรดเลือกโฟลเดอร์ปลายทางที่คุณต้องการย้ายไฟล์ดูภาพหน้าจอ:

5. จากนั้นคลิก OKกล่องพร้อมต์จะปรากฏขึ้นเพื่อเตือนให้คุณทราบว่ามีการย้ายไฟล์จำนวนเท่าใดปิดและคุณสามารถเห็นไฟล์ jpg, xlsx ที่ระบุถูกย้ายไปยังโฟลเดอร์ที่ระบุดูภาพหน้าจอ: