สมมติว่าคุณมีรายชื่อพนักงานภายในช่วงเวิร์กชีทและมีเป้าหมายที่จะสร้างโฟลเดอร์แต่ละโฟลเดอร์สำหรับแต่ละคนเพื่อจัดเก็บข้อมูล การสร้างแต่ละโฟลเดอร์ด้วยตนเองอาจใช้เวลานาน อย่างไรก็ตาม มีวิธีการที่มีประสิทธิภาพในการเร่งกระบวนการนี้ ในคู่มือนี้ ฉันจะแชร์วิธีการต่างๆ มากมายในการสร้างโฟลเดอร์อย่างรวดเร็วตามค่าของเซลล์ที่ระบุ

สร้างโฟลเดอร์ตามค่าของเซลล์

• โดยใช้คำสั่ง MD และ Notepad
• โดยใช้คุณลักษณะที่มีประสิทธิภาพ - Kutools for Excel
• โดยใช้โค้ด VBA

สร้างโฟลเดอร์และโฟลเดอร์ย่อยตามค่าเซลล์ด้วยรหัส VBA

สร้างโฟลเดอร์ตามค่าของเซลล์

ในส่วนนี้ เราจะสำรวจวิธีการต่างๆ โดยละเอียด โดยให้คำแนะนำทีละขั้นตอนที่ครอบคลุมเพื่อสร้างโฟลเดอร์ตามรายการค่าของเซลล์อย่างรวดเร็วและง่ายดาย

สร้างโฟลเดอร์จากรายการโดยใช้คำสั่ง MD และ Notepad

การเปลี่ยนรายการจาก Excel ให้เป็นโฟลเดอร์โดยใช้คำสั่ง MD และ Notepad เป็นเคล็ดลับอัจฉริยะที่ผสมผสานการเขียนสคริปต์แบบกลุ่มง่ายๆ เข้ากับความสามารถของ Excel ในการจัดระเบียบสิ่งต่างๆ วิธีนี้เหมาะสำหรับสร้างโฟลเดอร์จำนวนมากอย่างรวดเร็ว โดยไม่ต้องทำด้วยมือทั้งหมด คำแนะนำทีละขั้นตอนเพื่อให้งานนี้สำเร็จ:

ขั้นตอนที่ 1: ใช้คำสั่ง MD เพื่อสร้างสูตร

คัดลอกหรือใส่สูตรต่อไปนี้ลงในเซลล์ว่างถัดจากค่าเซลล์แรกของคุณ (เช่น B1) จากนั้นลากจุดจับเติมลงเพื่อใช้สูตรกับรายการทั้งหมดของคุณ

="MD "&A1

ขั้นตอนที่ 2: คัดลอกและวางสูตรลงในไฟล์ Notepad

1. ข่าวประชา Ctrl + C เพื่อคัดลอกเซลล์ด้วยสูตรคำสั่ง MD
2. จุดเปิด Notepad และกด Ctrl + V เพื่อวางคำสั่งลงในไฟล์ใหม่
   

ขั้นตอนที่ 3: บันทึกไฟล์ Notepad เป็นไฟล์ .bat

คลิก บันทึกเป็น จาก เนื้อไม่มีมัน แท็บใน Notepad ในไฟล์ บันทึกเป็น กล่องโต้ตอบ เลือกไดเร็กทอรีที่คุณต้องการสร้างหลายโฟลเดอร์ จากนั้นตั้งชื่อไฟล์นี้ด้วย a . ค้างคาว ส่วนขยาย. สุดท้ายคลิก ลด ปุ่ม. ดูภาพหน้าจอ:

ขั้นตอนที่ 4: ดับเบิลคลิกไฟล์ .bat เพื่อสร้างหลายโฟลเดอร์

1. ปิดไฟล์ Notepad นำทางไปยังโฟลเดอร์ที่คุณบันทึกไฟล์ .bat ไว้ก่อนหน้านี้
2. ตอนนี้ มาเป็นสักขีพยานในความมหัศจรรย์: ดับเบิลคลิกที่ไฟล์ แล้วคุณจะเห็นหลายโฟลเดอร์ถูกสร้างขึ้นพร้อมกัน ดูการสาธิตด้านล่าง:
   

สร้างโฟลเดอร์จากรายการโดยใช้เครื่องมืออันทรงพลัง - Kutools for Excel

ด้วยพลังอันทรงพลัง Kutools สำหรับ Excel's สร้างโฟลเดอร์จากสารบัญเซลล์ คุณสามารถสร้างโฟลเดอร์จากรายการ Excel ได้อย่างง่ายดายและรวดเร็ว แต่มันไม่ได้หยุดอยู่แค่โฟลเดอร์พื้นฐานเท่านั้น Kutools ยังช่วยให้คุณสร้างโครงสร้างที่ซับซ้อนด้วยโฟลเดอร์ย่อยหลายระดับได้ในคราวเดียว เพียงไม่กี่ขั้นตอนง่ายๆ ก็สามารถแปลงข้อมูลจาก Excel ให้เป็นระบบโฟลเดอร์ที่จัดระเบียบได้ ซึ่งช่วยเพิ่มประสิทธิภาพการทำงานของคุณได้อย่างมาก

หลังจากการติดตั้ง Kutools สำหรับ Excelกรุณาคลิกที่ Kutools พลัส > นำเข้าส่งออก > สร้างโฟลเดอร์จากสารบัญเซลล์ เพื่อเปิด สร้างโฟลเดอร์จากสารบัญเซลล์ กล่องโต้ตอบ:

1. เลือกค่าเซลล์ที่คุณต้องการสร้างโฟลเดอร์ตาม
2. จากนั้นให้คลิกที่ ปุ่มเพื่อระบุโฟลเดอร์ปลายทางที่คุณต้องการบันทึกโฟลเดอร์
3. สุดท้ายคลิก OK ปุ่ม
   

ผลลัพธ์:

Kutools จะประมวลผลรายการจากแผ่นงานของคุณและสร้างโฟลเดอร์สำหรับแต่ละรายการในปลายทางที่ระบุ นำทางไปยังโฟลเดอร์ปลายทางเพื่อดูผลลัพธ์ ดูภาพหน้าจอ:

สร้างโฟลเดอร์จากรายการโดยใช้โค้ด VBA

การใช้โค้ด VBA ใน Excel สามารถเปลี่ยนงานที่น่าเบื่อในการสร้างโฟลเดอร์จากรายการให้เป็นกระบวนการอัตโนมัติที่รวดเร็ว ส่วนนี้จะแสดงวิธีการใช้โค้ด VBA เพื่อสร้างโฟลเดอร์

ขั้นตอนที่ 1: เปิดตัวแก้ไขโมดูล VBA และคัดลอกโค้ด

1. ค้างไว้ ALT + F11 ใน Excel และจะเปิดไฟล์ Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง
2. คลิก สิ่งที่ใส่เข้าไป > โมดูลและวางรหัสต่อไปนี้ในไฟล์ โมดูล หน้าต่าง.
   รหัส VBA: สร้างโฟลเดอร์ตามรายการค่าของเซลล์

   Sub CreateFoldersFromSelection()
   'Updateby Extendoffice
       Dim FolderPath As String
       Dim Cell As Range
       Dim SelectedRange As Range
       Dim FolderName As String
       On Error Resume Next
       Set SelectedRange = Application.InputBox("Select the range with folder names", "Kutools for Excel", Type:=8)
       If SelectedRange Is Nothing Then Exit Sub
       On Error GoTo 0
       
       With Application.FileDialog(msoFileDialogFolderPicker)
           .Title = "Select the destination Folder"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           FolderPath = .SelectedItems(1) & "\"
       End With
       
       For Each Cell In SelectedRange
           FolderName = FolderPath & Cell.Value
           If Cell.Value <> "" And Not FolderExists(FolderName) Then
               MkDir FolderName
           End If
       Next Cell
   End Sub
   
   Function FolderExists(ByVal Path As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(Path) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

ขั้นตอนที่ 2: ดำเนินการโค้ด

1. หลังจากวางรหัสนี้แล้วโปรดกด F5 กุญแจสำคัญในการรันโค้ดนี้ ในกล่องพร้อมท์ ให้เลือกค่าเซลล์ที่คุณต้องการสร้างโฟลเดอร์ จากนั้นคลิก OK.
   
2. แล้วต่อไปนี้ เลือกโฟลเดอร์ปลายทาง หน้าต่าง ระบุเส้นทางปลายทางที่จะส่งออกโฟลเดอร์ที่สร้างขึ้น จากนั้นคลิก OK ปุ่มดูภาพหน้าจอ:
   

ผลลัพธ์:

หลังจากรันโค้ด VBA แล้ว ให้ตรงไปที่ไดเร็กทอรีปลายทางเพื่อดูผลลัพธ์ ที่นั่น คุณจะพบโฟลเดอร์ที่สร้างขึ้นใหม่ แต่ละโฟลเดอร์สอดคล้องกับรายการจากรายการ Excel ของคุณ ดูภาพหน้าจอ:

สร้างโฟลเดอร์และโฟลเดอร์ย่อยตามค่าเซลล์ด้วยรหัส VBA

ในบางครั้ง คุณอาจพบว่าตัวเองอยู่ในสถานการณ์ที่คุณจำเป็นต้องสร้างไม่เพียงแค่โฟลเดอร์เท่านั้น แต่ยังรวมถึงโฟลเดอร์ย่อยที่เกี่ยวข้องด้วย โดยทั้งหมดจะขึ้นอยู่กับข้อมูลภายในเซลล์ Excel เพื่อให้บรรลุภารกิจนี้ ฉันจะแนะนำโค้ด VBA ที่นี่

ขั้นตอนที่ 1: เตรียมข้อมูล

ขั้นแรก คุณควรป้อนข้อมูลตามภาพหน้าจอต่อไปนี้ วางชื่อโฟลเดอร์หลักในคอลัมน์แรก และชื่อของโฟลเดอร์ย่อยในคอลัมน์ที่สอง

ขั้นตอนที่ 2: เปิดตัวแก้ไขโมดูล VBA และคัดลอกโค้ด

1. ค้างไว้ ALT + F11 ใน Excel และจะเปิดไฟล์ Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง
2. คลิก สิ่งที่ใส่เข้าไป > โมดูลและวางรหัสต่อไปนี้ในไฟล์ โมดูล หน้าต่าง.
   รหัส VBA: สร้างโฟลเดอร์และโฟลเดอร์ย่อยตามค่าเซลล์

   Sub CreateFoldersAndSubfoldersWithUserInput()
   'Updateby Extendoffice
       Dim Rng As Range
       Dim Cell As Range
       Dim basePath As String
       Dim fldrPicker As FileDialog
       Dim FolderPath As String, subfolderPath As String
       On Error Resume Next
       Set Rng = Application.InputBox("Select the range of cells (two columns: one is folder column, another s subfolder column):", "Kutools for Excel", Type:=8)
       If Rng Is Nothing Then Exit Sub
       On Error GoTo 0
       Set fldrPicker = Application.FileDialog(msoFileDialogFolderPicker)
       With fldrPicker
           .Title = "Select the Base Folder Path"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           basePath = .SelectedItems(1)
       End With
       If Right(basePath, 1) <> "\" Then basePath = basePath & "\"
       For Each Cell In Rng.Columns(1).Cells
           If Not Cell.Value = "" Then
               FolderPath = basePath & Cell.Value
               If Not FolderExists(FolderPath) Then MkDir FolderPath
               If Not Cell.Offset(0, 1).Value = "" Then
                   subfolderPath = FolderPath & "\" & Cell.Offset(0, 1).Value
                   If Not FolderExists(subfolderPath) Then MkDir subfolderPath
               End If
           End If
       Next Cell
   End Sub
   
   Function FolderExists(FolderPath As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(FolderPath) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

ขั้นตอนที่ 3: ดำเนินการโค้ด

1. หลังจากวางรหัสนี้แล้วโปรดกด F5 กุญแจสำคัญในการรันโค้ดนี้ ในกล่องพร้อมท์ ให้เลือกค่าเซลล์ที่คุณต้องการสร้างโฟลเดอร์ จากนั้นคลิก OK.
   
2. ในหน้าต่างที่เด้งออกมาต่อไปนี้ ให้ระบุเส้นทางปลายทางที่จะส่งออกโฟลเดอร์ที่สร้างขึ้น จากนั้นคลิก OK ปุ่มดูภาพหน้าจอ:
   

ผลลัพธ์:

หลังจากรันโค้ด VBA แล้ว ให้ไปที่ไดเร็กทอรีปลายทางเพื่อดูผลลัพธ์ คุณจะพบว่าโฟลเดอร์และโฟลเดอร์ย่อยตามลำดับตามค่าของเซลล์ได้ถูกสร้างขึ้นเรียบร้อยแล้วตามภาพต่อไปนี้:

บทความที่เกี่ยวข้อง: