วิธีการนับจำนวนหน้าของไฟล์ Pdf ใน Excel

หากมีไฟล์ Pdf หลายไฟล์ในโฟลเดอร์เฉพาะตอนนี้คุณต้องการแสดงชื่อไฟล์ทั้งหมดเหล่านี้ในแผ่นงานและรับหมายเลขหน้าของแต่ละไฟล์ คุณจะจัดการกับงานนี้ใน Excel อย่างรวดเร็วและง่ายดายได้อย่างไร

นับจำนวนหน้าของไฟล์ Pdf จากโฟลเดอร์ในแผ่นงานด้วยรหัส VBA

นับจำนวนหน้าของไฟล์ Pdf จากโฟลเดอร์ในแผ่นงานด้วยรหัส VBA

อาจเป็นรหัส VBA ต่อไปนี้สามารถช่วยให้คุณแสดงชื่อไฟล์ Pdf ทั้งหมดและหมายเลขหน้าแต่ละรายการในแผ่นงานได้โปรดดำเนินการดังนี้:

1. เปิดแผ่นงานที่คุณต้องการรับไฟล์ Pdf และหมายเลขหน้า

2. กด ALT + F11 และจะเปิดไฟล์ Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

3. คลิก สิ่งที่ใส่เข้าไป > โมดูลและวางมาโครต่อไปนี้ในไฟล์ โมดูล หน้าต่าง.

รหัส VBA: แสดงชื่อไฟล์ Pdf และหมายเลขหน้าทั้งหมดในแผ่นงาน:

Sub Test()
    Dim I As Long
    Dim xRg As Range
    Dim xStr As String
    Dim xFd As FileDialog
    Dim xFdItem As Variant
    Dim xFileName As String
    Dim xFileNum As Long
    Dim RegExp As Object
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    If xFd.Show = -1 Then
        xFdItem = xFd.SelectedItems(1) & Application.PathSeparator
        xFileName = Dir(xFdItem & "*.pdf", vbDirectory)
        Set xRg = Range("A1")
        Range("A:B").ClearContents
        Range("A1:B1").Font.Bold = True
        xRg = "File Name"
        xRg.Offset(0, 1) = "Pages"
        I = 2
        xStr = ""
        Do While xFileName <> ""
            Cells(I, 1) = xFileName
            Set RegExp = CreateObject("VBscript.RegExp")
            RegExp.Global = True
            RegExp.Pattern = "/Type\s*/Page[^s]"
            xFileNum = FreeFile
            Open (xFdItem & xFileName) For Binary As #xFileNum
                xStr = Space(LOF(xFileNum))
                Get #xFileNum, , xStr
            Close #xFileNum
            Cells(I, 2) = RegExp.Execute(xStr).Count
            I = I + 1
            xFileName = Dir
        Loop
        Columns("A:B").AutoFit
    End If
End Sub

4. หลังจากวางรหัสแล้วกด F5 กุญแจสำคัญในการเรียกใช้รหัสนี้และไฟล์ หมวดหมู่สินค้า หน้าต่างจะเปิดออกมาโปรดเลือกโฟลเดอร์ที่มีไฟล์ Pdf ที่คุณต้องการแสดงรายการและนับหมายเลขหน้าดูภาพหน้าจอ:

5. จากนั้นคลิก OK ปุ่มชื่อไฟล์ Pdf และหมายเลขหน้าทั้งหมดจะแสดงอยู่ในแผ่นงานปัจจุบันดูภาพหน้าจอ: