วิธีการต่อคอลัมน์เซลล์และรักษาสีข้อความใน Excel

อย่างที่เราทราบกันดีว่าในขณะที่การต่อหรือรวมคอลัมน์เซลล์เป็นคอลัมน์เดียวการจัดรูปแบบเซลล์ (เช่นสีฟอนต์ข้อความการจัดรูปแบบตัวเลข ฯลฯ ) จะหายไป บทความนี้ผมจะแนะนำเทคนิคบางประการในการรวมคอลัมน์ของเซลล์ให้เป็นหนึ่งเดียวและรักษาสีข้อความให้ง่ายที่สุดใน Excel

เชื่อมต่อคอลัมน์ของเซลล์และรักษาสีแบบอักษรของข้อความด้วยรหัส VBA

เชื่อมต่อคอลัมน์ของเซลล์และรักษาสีแบบอักษรของข้อความด้วยรหัส VBA

เพื่อให้งานนี้เสร็จสิ้นใน Excel รหัส VBA ต่อไปนี้อาจช่วยคุณได้โปรดทำตามนี้:

1. กด ALT + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2. คลิก สิ่งที่ใส่เข้าไป > โมดูลและวางรหัสต่อไปนี้ในไฟล์ หน้าต่างโมดูล.

รหัส VBA: ต่อคอลัมน์เซลล์และรักษาสีข้อความ:

Sub MergeFormatCell()
'Updateby Extendoffice
    Dim xSRg As Range
    Dim xDRg As Range
    Dim xRgEachRow As Range
    Dim xRgEach As Range
    Dim xRgVal As String
    Dim I As Integer
    Dim xRgLen As Integer
    Dim xSRgRows As Integer
    Dim xAddress As String
    On Error Resume Next
    xAddress = ActiveWindow.RangeSelection.Address
    Set xSRg = Application.InputBox("Please select cell columns to concatenate:", "KuTools For Excel", xAddress, , , , , 8)
    If xSRg Is Nothing Then Exit Sub
    xSRgRows = xSRg.Rows.Count
    Set xDRg = Application.InputBox("Please select cells to output the result:", "KuTools For Excel", , , , , , 8)
    If xDRg Is Nothing Then Exit Sub
    Set xDRg = xDRg(1)
    For I = 1 To xSRgRows
        xRgLen = 1
        With xDRg.Offset(I - 1)
            .Value = vbNullString
            .ClearFormats
			.NumberFormat = "@"
            Set xRgEachRow = xSRg(1).Offset(I - 1).Resize(1, xSRg.Columns.Count)
            For Each xRgEach In xRgEachRow
                .Value = .Value & Trim(xRgEach.Value) & " "
            Next
            For Each xRgEach In xRgEachRow
                xRgVal = xRgEach.Value
                With .Characters(xRgLen, Len(Trim(xRgVal))).Font
                .Name = xRgEach.Font.Name
                .FontStyle = xRgEach.Font.FontStyle
                .Size = xRgEach.Font.Size
                .Strikethrough = xRgEach.Font.Strikethrough
                .Superscript = xRgEach.Font.Superscript
                .Subscript = xRgEach.Font.Subscript
                .OutlineFont = xRgEach.Font.OutlineFont
                .Shadow = xRgEach.Font.Shadow
                .Underline = xRgEach.Font.Underline
                .ColorIndex = xRgEach.Font.ColorIndex
                End With
                xRgLen = xRgLen + Len(Trim(xRgVal)) + 1
            Next
        End With
    Next I
End Sub

3. จากนั้นกด F5 คีย์เพื่อเรียกใช้รหัสนี้และกล่องพร้อมต์จะปรากฏขึ้นเพื่อเตือนให้คุณเลือกช่วงข้อมูลที่คุณต้องการรวมกับสีข้อความดูภาพหน้าจอ:

4. จากนั้นคลิก OKกล่องโต้ตอบอื่นจะปรากฏขึ้นโปรดเลือกเซลล์ที่คุณต้องการแสดงผลลัพธ์รวมดูภาพหน้าจอ:

5. จากนั้นคลิก OK คอลัมน์จะถูกเชื่อมต่อกันโดยไม่สูญเสียสีข้อความดังภาพหน้าจอต่อไปนี้: