วิธีค้นหาและแทนที่ข้อความจากนั้นรักษาการจัดรูปแบบใน Excel

ฟังก์ชันค้นหาและแทนที่มีประสิทธิภาพและเป็นประโยชน์เมื่อเราต้องการค้นหาค่าเฉพาะและแทนที่ด้วยค่าอื่น แต่ถ้ามีช่วงของเซลล์และบางเซลล์มีค่าการจัดรูปแบบที่แตกต่างกัน ในกรณีนี้ในการค้นหาและแทนที่ค่าโดยฟังก์ชัน Find and Replace จะทำให้การจัดรูปแบบของค่าในเซลล์ดังรูปด้านล่างแสดงภาพหน้าจอเราจะรักษาการจัดรูปแบบของค่าในแต่ละเซลล์ในขณะที่ค้นหาและแทนที่ใน Excel ได้อย่างไร

ค้นหาและแทนที่รักษาการจัดรูปแบบด้วยรหัสมาโคร

ค้นหาและแทนที่รักษาการจัดรูปแบบด้วยรหัสมาโคร

ไม่มีวิธีการอื่นนอกจากโค้ดมาโครสามารถช่วยคุณค้นหาและแทนที่ข้อความและรักษาการจัดรูปแบบได้

1 กด Alt + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2 คลิก สิ่งที่ใส่เข้าไป > โมดูลและวางโค้ดด้านล่างลงในสคริปต์

VBA: ค้นหาและแทนที่รักษาการจัดรูปแบบ

Sub CharactersReplace(Rng As Range, FindText As String, ReplaceText As String, Optional MatchCase As Boolean = False)
  'UpdatebyExtendoffice20160711
    Dim I As Long
    Dim xLenFind As Long
    Dim xLenRep As Long
    Dim K As Long
    Dim xValue As String
    Dim M As Long
    Dim xCell As Range
    xLenFind = Len(FindText)
    xLenRep = Len(ReplaceText)
    If Not MatchCase Then M = 1
    For Each xCell In Rng
        If VarType(xCell) = vbString Then
            xValue = xCell.Value
            K = 0
            For I = 1 To Len(xValue)
              If StrComp(Mid$(xValue, I, xLenFind), FindText, M) = 0 Then
                xCell.Characters(I + K, xLenFind).Insert ReplaceText
                K = K + xLenRep - xLenFind
              End If
            Next
        End If
    Next
End Sub

Sub Test_CharactersReplace()
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Select a range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Call CharactersReplace(xRg, "KK", "Kutools", True)
End Sub

ปลาย: ในรหัส  KK คือสตริงที่คุณต้องการค้นหาและ Kutools คือสตริงที่คุณต้องการแทนที่คุณสามารถเปลี่ยนได้ตามต้องการ

3 กด F5 ที่สำคัญกล่องโต้ตอบจะปรากฏขึ้นเพื่อให้คุณเลือกช่วงที่จะค้นหาและแทนที่ดูภาพหน้าจอ:

4. คลิกตกลงและสตริงเฉพาะในเซลล์ที่เลือกจะถูกแทนที่ด้วยอื่น ๆ และคงการจัดรูปแบบไว้