วิธีการนำเข้าไฟล์ csv / text / xml หลายชุดใน Excel อย่างรวดเร็ว

ใน Excel คุณอาจเชื่อมโยงกับการบันทึกสมุดงานเป็นไฟล์ csv ไฟล์ข้อความหรือไฟล์ xml แต่คุณเคยพยายามนำเข้าไฟล์ csv / text / xml หลายไฟล์จากโฟลเดอร์ลงในสมุดงานหรือแผ่นงานหรือไม่? ในบทความนี้ฉันแนะนำวิธีการบางอย่างเพื่อนำเข้าแบทช์อย่างรวดเร็ว

นำเข้าไฟล์ข้อความหลายไฟล์จากโฟลเดอร์ไปยังแต่ละแผ่นงานของสมุดงานด้วย VBA

ในการนำเข้าไฟล์ข้อความจากโฟลเดอร์ไปยังสมุดงานคุณสามารถใช้ VBA ด้านล่างเพื่อจัดการได้อย่างรวดเร็ว

1. เปิดใช้งานสมุดงานเปล่าแล้วกด Alt + F11 กุญแจเพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2 คลิก สิ่งที่ใส่เข้าไป > โมดูลและวาง VBA ลงในไฟล์ โมดูล หน้าต่าง

VBA: นำเข้าไฟล์ข้อความทั้งหมดจากโฟลเดอร์ลงในสมุดงาน

Sub LoadPipeDelimitedFiles()
'UpdatebyKutoolsforExcel20151214
    Dim xStrPath As String
    Dim xFileDialog As FileDialog
    Dim xFile As String
    Dim xCount As Long
    On Error GoTo ErrHandler
    Set xFileDialog = Application.FileDialog(msoFileDialogFolderPicker)
    xFileDialog.AllowMultiSelect = False
    xFileDialog.Title = "Select a folder [Kutools for Excel]"
    If xFileDialog.Show = -1 Then
        xStrPath = xFileDialog.SelectedItems(1)
    End If
    If xStrPath = "" Then Exit Sub
    Application.ScreenUpdating = False
    xFile = Dir(xStrPath & "\*.txt")
    Do While xFile <> ""
        xCount = xCount + 1
        Sheets(xCount).Select
        With ActiveSheet.QueryTables.Add(Connection:="TEXT;" _
          & xStrPath & "\" & xFile, Destination:=Range("A1"))
            .Name = "a" & xCount
            .FieldNames = True
            .RowNumbers = False
            .FillAdjacentFormulas = False
            .PreserveFormatting = True
            .RefreshOnFileOpen = False
            .RefreshStyle = xlInsertDeleteCells
            .SavePassword = False
            .SaveData = True
            .AdjustColumnWidth = True
            .RefreshPeriod = 0
            .TextFilePromptOnRefresh = False
            .TextFilePlatform = 437
            .TextFileStartRow = 1
            .TextFileParseType = xlDelimited
            .TextFileTextQualifier = xlTextQualifierDoubleQuote
            .TextFileConsecutiveDelimiter = False
            .TextFileTabDelimiter = False
            .TextFileSemicolonDelimiter = False
            .TextFileCommaDelimiter = False
            .TextFileSpaceDelimiter = False
            .TextFileOtherDelimiter = "|"
            .TextFileColumnDataTypes = Array(1, 1, 1)
            .TextFileTrailingMinusNumbers = True
            .Refresh BackgroundQuery:=False
            xFile = Dir
        End With
    Loop
    Application.ScreenUpdating = True
    Exit Sub
ErrHandler:
    MsgBox "no files txt", , "Kutools for Excel"
End Sub

3 กด F5 คีย์หรือ วิ่ง เพื่อเรียกใช้ VBA และเลือกโฟลเดอร์ที่คุณต้องการนำเข้าไฟล์ข้อความจากในกล่องโต้ตอบ popping ดูภาพหน้าจอ:

4. แล้วคลิก OKและไฟล์ข้อความแต่ละไฟล์ในโฟลเดอร์ที่เลือกจะถูกนำเข้าในแผ่นงานเดียวของสมุดงานที่ใช้งานอยู่ ดูภาพหน้าจอ:

ปลดล็อก Excel Magic ด้วย Kutools AI

• การดำเนินการอย่างชาญฉลาด: ดำเนินการกับเซลล์ วิเคราะห์ข้อมูล และสร้างแผนภูมิ ทั้งหมดนี้ขับเคลื่อนด้วยคำสั่งง่ายๆ
• สูตรที่กำหนดเอง: สร้างสูตรที่ปรับแต่งโดยเฉพาะเพื่อปรับปรุงขั้นตอนการทำงานของคุณ
• การเข้ารหัส VBA: เขียนและใช้งานโค้ด VBA ได้อย่างง่ายดาย
• การตีความสูตร: เข้าใจสูตรที่ซับซ้อนได้อย่างง่ายดาย
• การแปลข้อความ: ทลายกำแพงด้านภาษาภายในสเปรดชีตของคุณ

ปรับปรุงความสามารถ Excel ของคุณด้วยเครื่องมือที่ขับเคลื่อนด้วย AI ดาวน์โหลดเดี๋ยวนี้ และสัมผัสประสิทธิภาพอย่างที่ไม่เคยมีมาก่อน!

นำเข้าไฟล์ csv หลายไฟล์จากโฟลเดอร์ลงในแผ่นงานเดียวด้วย VBA

ในการนำเข้าไฟล์ csv ทั้งหมดจากโฟลเดอร์ลงในแผ่นงานเดียวคุณสามารถใช้โค้ด VBA ด้านล่าง

1. เปิดใช้งานแผ่นงานเปล่าแล้วกด Alt + F11 กุญแจเพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2 คลิก สิ่งที่ใส่เข้าไป > โมดูลและวาง VBA ด้านล่างลงในไฟล์ โมดูล หน้าต่าง

VBA: นำเข้าไฟล์ csv จากโฟลเดอร์ลงในแผ่นงานเดียว

Sub ImportCSVsWithReference()
'UpdatebyKutoolsforExcel20151214
    Dim xSht  As Worksheet
    Dim xWb As Workbook
    Dim xStrPath As String
    Dim xFileDialog As FileDialog
    Dim xFile As String
    On Error GoTo ErrHandler
    Set xFileDialog = Application.FileDialog(msoFileDialogFolderPicker)
    xFileDialog.AllowMultiSelect = False
    xFileDialog.Title = "Select a folder [Kutools for Excel]"
    If xFileDialog.Show = -1 Then
        xStrPath = xFileDialog.SelectedItems(1)
    End If
    If xStrPath = "" Then Exit Sub
    Set xSht = ThisWorkbook.ActiveSheet
    If MsgBox("Clear the existing sheet before importing?", vbYesNo, "Kutools for Excel") = vbYes Then xSht.UsedRange.Clear
    Application.ScreenUpdating = False
    xFile = Dir(xStrPath & "\" & "*.csv")
    Do While xFile <> ""
        Set xWb = Workbooks.Open(xStrPath & "\" & xFile)
        Columns(1).Insert xlShiftToRight
        Columns(1).SpecialCells(xlBlanks).Value = ActiveSheet.Name
        ActiveSheet.UsedRange.Copy xSht.Range("A" & Rows.Count).End(xlUp).Offset(1)
        xWb.Close False
        xFile = Dir
    Loop
    Application.ScreenUpdating = True
    Exit Sub
ErrHandler:
    MsgBox "no files csv", , "Kutools for Excel"
End Sub

3 กด F5 คีย์หรือคลิก วิ่ง เพื่อเรียกใช้งาน VBA และกล่องโต้ตอบจะปรากฏขึ้นเพื่อเลือกโฟลเดอร์ที่คุณต้องการนำเข้าไฟล์ csv ทั้งหมด ดูภาพหน้าจอ:

4 คลิก OKและกล่องโต้ตอบจะปรากฏขึ้นเพื่อเตือนคุณหากล้างเนื้อหาของแผ่นงานที่ใช้งานอยู่ก่อนนำเข้าฉันคลิกที่นี่ ใช่. ดูภาพหน้าจอ:

หลังจากคลิก ใช่ไฟล์ csv ทั้งหมดในโฟลเดอร์ที่เลือกจะถูกนำเข้าไปในแผ่นงานปัจจุบันและวางข้อมูลจากคอลัมน์ A ไปทางขวา ดูภาพหน้าจอ:

เคล็ดลับ: หากคุณต้องการวางไฟล์ csv ในแนวนอนในแผ่นงานคุณสามารถใช้ VBA ด้านล่าง

Sub ImportCSVsWithReferenceI()
'UpdatebyKutoolsforExcel20151214
    Dim xSht  As Worksheet
    Dim xWb As Workbook
    Dim xStrPath As String
    Dim xFileDialog As FileDialog
    Dim xFile As String
    Dim xCount As Long
    On Error GoTo ErrHandler
    Set xFileDialog = Application.FileDialog(msoFileDialogFolderPicker)
    xFileDialog.AllowMultiSelect = False
    xFileDialog.Title = "Select a folder [Kutools for Excel]"
    If xFileDialog.Show = -1 Then
        xStrPath = xFileDialog.SelectedItems(1)
    End If
    If xStrPath = "" Then Exit Sub
    Set xSht = ThisWorkbook.ActiveSheet
    If MsgBox("Clear the existing sheet before importing?", vbYesNo, "Kutools for Excel") = vbYes Then
        xSht.UsedRange.Clear
        xCount = 1
    Else
        xCount = xSht.Cells(3, Columns.Count).End(xlToLeft).Column + 1
    End If
    Application.ScreenUpdating = False
    xFile = Dir(xStrPath & "\" & "*.csv")
    Do While xFile <> ""
        Set xWb = Workbooks.Open(xStrPath & "\" & xFile)
        Rows(1).Insert xlShiftDown
        Range("A1") = ActiveSheet.Name
        ActiveSheet.UsedRange.Copy xSht.Cells(1, xCount)
        xWb.Close False
        xFile = Dir
        xCount = xSht.Cells(3, Columns.Count).End(xlToLeft).Column + 1
    Loop
    Application.ScreenUpdating = True
    Exit Sub
ErrHandler:
    MsgBox "no files csv", , "Kutools for Excel"
End Sub 

นำเข้าไฟล์ xml หลายไฟล์จากโฟลเดอร์ลงในแผ่นงานเดียวด้วย VBA

หากคุณต้องการนำเข้าไฟล์ XML ทั้งหมดจากโฟลเดอร์ลงในแผ่นงานเดียวคุณสามารถใช้โค้ด VBA ด้านล่าง

1. เลือกแผ่นงานเปล่าที่คุณต้องการวางข้อมูลที่นำเข้าแล้วกด Alt + F11 คีย์เพื่อเปิดใช้งาน Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2 คลิก สิ่งที่ใส่เข้าไป > โมดูลวางรหัส VBA ลงในไฟล์ โมดูล หน้าต่าง

VBA: นำเข้าไฟล์ XML จากโฟลเดอร์ลงในแผ่นงาน

Sub From_XML_To_XL()
'UpdatebyKutoolsforExcel20151214
    Dim xWb As Workbook
    Dim xSWb As Workbook
    Dim xStrPath As String
    Dim xFileDialog As FileDialog
    Dim xFile As String
    Dim xCount As Long
    On Error GoTo ErrHandler
    Set xFileDialog = Application.FileDialog(msoFileDialogFolderPicker)
    xFileDialog.AllowMultiSelect = False
    xFileDialog.Title = "Select a folder [Kutools for Excel]"
    If xFileDialog.Show = -1 Then
        xStrPath = xFileDialog.SelectedItems(1)
    End If
    If xStrPath = "" Then Exit Sub
    Application.ScreenUpdating = False
    Set xSWb = ThisWorkbook
    xCount = 1
    xFile = Dir(xStrPath & "\*.xml")
    Do While xFile <> ""
        Set xWb = Workbooks.OpenXML(xStrPath & "\" & xFile)
        xWb.Sheets(1).UsedRange.Copy xSWb.Sheets(1).Cells(xCount, 1)
        xWb.Close False
        xCount = xSWb.Sheets(1).UsedRange.Rows.Count + 2
        xFile = Dir()
    Loop
    Application.ScreenUpdating = True
    xSWb.Save
    Exit Sub
ErrHandler:
    MsgBox "no files xml", , "Kutools for Excel"
End Sub

3 คลิก วิ่ง หรือ F5 เพื่อเรียกใช้ VBA และเลือกโฟลเดอร์ในกล่องโต้ตอบ popping ดูภาพหน้าจอ:

4 คลิก OKและไฟล์ XML ทั้งหมดในโฟลเดอร์ที่เลือกจะถูกนำเข้าสู่แผ่นงานที่ใช้งานอยู่

นำเข้าหรือรวมไฟล์ xml / csv หลายไฟล์ลงในแผ่นงานหรือสมุดงานด้วย Kutools for Excel

หากคุณไม่คุ้นเคยกับ VBA ไม่ต้องกังวลที่นี่ฉันขอแนะนำเครื่องมือที่มีประโยชน์ - Kutools สำหรับ Excel สำหรับคุณ. ด้วยประสิทธิภาพ รวมกัน ยูทิลิตี้คุณสามารถรวมไฟล์ xml หรือไฟล์ csv หลายไฟล์ลงในสมุดงานเดียวหรือหนึ่งแผ่นงาน Excel ได้อย่างรวดเร็ว

หลังจากการติดตั้ง Kutools สำหรับ Excel โปรดทำดังนี้:(ดาวน์โหลด Kutools for Excel ฟรีทันที!)

1. ใช้งาน Excel แล้วคลิก Kutools พลัส > รวมกัน. ดูภาพหน้าจอ：

2. และใน ขั้นตอนที่ 1 ของการรวม โต้ตอบเลือกตัวเลือกการแยกหนึ่งรายการตามที่คุณต้องการ ดูภาพหน้าจอ:

3 คลิก ถัดไป เพื่อไปที่ ขั้นตอนที่ 2 ของการรวมคลิก เพิ่ม เพื่อเพิ่มไฟล์จากโฟลเดอร์ต่างๆหรือไฟล์จากโฟลเดอร์หนึ่งไปยัง สมุดงาน รายการและคุณสามารถระบุแผ่นงานที่คุณต้องการรวมได้ แผ่นงาน รายการส่วนที่ถูกต้อง ดูภาพหน้าจอ:

4 คลิก ถัดไป ไปยังขั้นตอนสุดท้ายของ รวมกันและคุณสามารถระบุตัวเลือกการรวม

5 คลิก เสร็จสิ้นกล่องโต้ตอบจะปรากฏขึ้นเพื่อเตือนให้คุณเลือกตำแหน่งที่จะบันทึกผลการรวมใหม่ ดูภาพหน้าจอ:

6 คลิก ลด. แผ่นงานที่เพิ่มทั้งหมดรวมกันเป็นแผ่นงานใหม่

เคล็ดลับ: ด้วยระบบเส้นทาง รวมกันคุณยังสามารถรวมหลาย ๆ ไฟล์ CSV สร้างหลายโฟลเดอร์หรือหนึ่งโฟลเดอร์เป็นแผ่นเดียวหรือสมุดงาน

ส่งออกแต่ละแผ่นเป็น csv / text / pdf ไปยังโฟลเดอร์ด้วย Kutools for Excel

หากคุณต้องการส่งออกแต่ละแผ่นเป็นไฟล์ csv / text / pdf ไปยังโฟลเดอร์ Kutools สำหรับ Excel's แยกสมุดงาน ยูทิลิตี้สามารถช่วยคุณได้

หลังจาก ดาวน์โหลดและติดตั้งฟรี Kutools สำหรับ Excel โปรดทำดังนี้:

1. เปิดใช้งานสมุดงานที่คุณต้องการส่งออกเวิร์กชีตแล้วคลิก Kutools พลัส > สมุดงาน > แยกสมุดงาน. ดูภาพหน้าจอ:

2 ใน แยกสมุดงาน คุณสามารถตรวจสอบชื่อแผ่นงานที่คุณต้องการส่งออกโดยค่าเริ่มต้นแผ่นงานทั้งหมดจะถูกตรวจสอบและตรวจสอบ ระบุรูปแบบการบันทึก และเลือกรูปแบบไฟล์ที่คุณต้องการบันทึกจากรายการแบบหล่นลงด้านล่าง ดูภาพหน้าจอ:

3 คลิก แยก และเลือกโฟลเดอร์ที่จะบันทึกไฟล์แยกในไฟล์ เรียกดูโฟลเดอร์ กล่องโต้ตอบดูภาพหน้าจอ:

4 คลิก OKตอนนี้แผ่นงานที่ตรวจสอบทั้งหมดจะถูกส่งออกเป็นรูปแบบไฟล์ใหม่ในโฟลเดอร์ที่เลือก

บทความญาติ:

• วิธีแปลงไฮเปอร์ลิงก์เป็นข้อความธรรมดาใน Excel
• วิธีการแปลงเลขฐานสิบเป็นเลขฐานสอง / ฐานแปด / เลขฐานสิบหกหรือในทางกลับกันใน Excel
• วิธีแทรกอัตราแลกเปลี่ยนสดใน Excel