วิธีเรียกใช้มาโครหลายรายการจากเมนูคลิกขวาใน Excel

หากมีมาโคร vba หลายตัวในสมุดงานของคุณคุณควรเปิดหน้าต่าง VBA จากนั้นเลือกมาโครเมื่อคุณต้องการเรียกใช้โค้ด ในบทความนี้จะพูดถึงวิธีเรียกใช้มาโครจากเมนูคลิกขวาเพื่อให้งานของคุณมีประสิทธิภาพมากขึ้นตามภาพหน้าจอด้านซ้าย

เรียกใช้มาโครหลายรายการจากเมนูคลิกขวาด้วยรหัส VBA

เรียกใช้มาโครหลายรายการจากเมนูคลิกขวาด้วยรหัส VBA

ในการเรียกใช้รหัสแมโครภายในสมุดงานจากเมนูคลิกขวาขั้นตอนต่อไปนี้อาจช่วยคุณได้โปรดดำเนินการดังนี้:

1. เจาะรู Alt + F11 คีย์เพื่อเปิด Microsoft Visual Basic สำหรับแอปพลิเคชัน หน้าต่าง

2. จากนั้นดับเบิลคลิก สมุดงานนี้ ทางด้านซ้าย โครงการ บานหน้าต่างจากนั้นคัดลอกและวางโค้ด VBA ด้านล่างลงในโมดูลเปล่า

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3. ยังคงอยู่ใน Microsoft Visual Basic สำหรับแอปพลิเคชัน โปรดคลิก สิ่งที่ใส่เข้าไป > โมดูลและวางรหัสต่อไปนี้ลงในโมดูลนี้

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4. หลังจากวางรหัสแล้วคลิก เครื่องมือ > อ้างอิงและใน เอกสารอ้างอิง -VBAProject กล่องโต้ตอบจะปรากฏขึ้นจากนั้นตรวจสอบ Microsoft Visual Basic for Applications Extensibility 5.3 ตัวเลือกใน อ้างอิงที่มีอยู่ กล่องรายการดูภาพหน้าจอ:

5. จากนั้นคลิก OK หากต้องการออกจากกล่องโต้ตอบตอนนี้คุณควรบันทึกสมุดงานนี้เป็น สมุดงานที่เปิดใช้งานแมโคร Excel รูปแบบดูภาพหน้าจอ:

6. ในที่สุดโปรดรีสตาร์ทสมุดงานเพื่อรับเอฟเฟกต์รหัสและตอนนี้เมื่อคุณคลิกขวาที่เซลล์ a เรียกใช้ Macro ตัวเลือกจะถูกแทรกลงในเมนูคลิกขวาและมาโครทั้งหมดในสมุดงานของคุณจะแสดงรายการในเมนูย่อยดังภาพหน้าจอต่อไปนี้:

7. จากนั้นคุณสามารถเรียกใช้โค้ดได้โดยคลิกที่มัน